[arch-commits] Commit in libtool/repos (staging-x86_64 staging-x86_64/PKGBUILD)
Bartłomiej Piotrowski
bpiotrowski at archlinux.org
Wed May 2 20:36:14 UTC 2018
Date: Wednesday, May 2, 2018 @ 20:36:13
Author: bpiotrowski
Revision: 323300
archrelease: copy trunk to staging-x86_64
Added:
libtool/repos/staging-x86_64/
libtool/repos/staging-x86_64/PKGBUILD
(from rev 323299, libtool/trunk/PKGBUILD)
----------+
PKGBUILD | 51 +++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 51 insertions(+)
Copied: libtool/repos/staging-x86_64/PKGBUILD (from rev 323299, libtool/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2018-05-02 20:36:13 UTC (rev 323300)
@@ -0,0 +1,51 @@
+# $Id$
+# Maintainer: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Allan McRae <allan at archlinux.org>
+# Contributor: judd <jvinet at zeroflux.org>
+
+# NOTE: requires rebuilt with each new gcc version
+
+pkgname=libtool
+pkgver=2.4.6+40+g6ca5e224
+pkgrel=6
+_gccver=8.1.0
+pkgdesc='A generic library support script'
+arch=(x86_64)
+url='http://www.gnu.org/software/libtool'
+license=(GPL)
+groups=(base-devel)
+depends=(sh tar glibc)
+makedepends=("gcc>=$_gccver" git help2man)
+checkdepends=(gcc-fortran)
+provides=("libltdl=$pkgver" "libtool-multilib=$pkgver")
+conflicts=(libltdl libtool-multilib)
+replaces=(libltdl libtool-multilib)
+_commit=6ca5e224bc7bcc114a9ba2cf5dcf0fbf0ec40c9f
+source=(git+https://git.savannah.gnu.org/git/libtool.git#commit=$_commit)
+md5sums=('SKIP')
+
+pkgver() {
+ cd libtool
+ git describe --tags | sed 's/-/+/g;s/^v//'
+}
+
+prepare() {
+ cd libtool
+ ./bootstrap
+}
+
+build() {
+ cd libtool
+ ./configure --prefix=/usr lt_cv_sys_lib_dlsearch_path_spec="/usr/lib /usr/lib32"
+ make
+}
+
+check() {
+ cd libtool
+ make check gl_public_submodule_commit=
+}
+
+package() {
+ cd libtool
+ make DESTDIR="$pkgdir" install
+}
More information about the arch-commits
mailing list