[arch-commits] Commit in (4 files)

[Sven-Hendrik Haase]

    Date: Monday, May 7, 2018 @ 18:39:25
  Author: svenstaro
Revision: 319276

Add glbinding as a new dep of arrayfire

Added:
  glbinding/
  glbinding/repos/
  glbinding/trunk/
  glbinding/trunk/PKGBUILD

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Added: glbinding/trunk/PKGBUILD
===================================================================
--- glbinding/trunk/PKGBUILD	                        (rev 0)
+++ glbinding/trunk/PKGBUILD	2018-05-07 18:39:25 UTC (rev 319276)
@@ -0,0 +1,49 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
+# Contributor: carstene1ns <arch carsten-teibes de> - http://git.io/ctPKG
+# Contributor: Xentec <xentec at aix0 dot eu>
+
+pkgname=glbinding
+pkgver=2.1.4
+pkgrel=1
+pkgdesc="A C++ binding for the OpenGL API, generated using the gl.xml specification"
+arch=('x86_64')
+url="http://www.glbinding.org"
+license=('MIT')
+depends=('libgl' 'glfw')
+makedepends=('cmake' 'mesa')
+checkdepends=('python')
+source=($pkgname-$pkgver.tar.gz::"https://github.com/cginternals/glbinding/archive/v$pkgver.tar.gz")
+sha256sums=('cb5971b086c0d217b2304d31368803fd2b8c12ee0d41c280d40d7c23588f8be2')
+
+prepare() {
+  cd $pkgname-$pkgver
+
+  rm -rf build
+  mkdir build
+}
+
+build() {
+  cd $pkgname-$pkgver/build
+
+  cmake .. \
+      -DCMAKE_INSTALL_PREFIX=/usr \
+      -DCMAKE_BUILD_TYPE=Release \
+      -DOPTION_BUILD_TESTS=ON
+  make
+}
+
+check() {
+  cd $pkgname-$pkgver/build
+
+  make test
+}
+
+package() {
+  cd $pkgname-$pkgver
+
+  make -C build DESTDIR="$pkgdir/" install
+
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+  install -d "$pkgdir"/usr/share/doc/$pkgname
+  install -m644 README.md AUTHORS "$pkgdir"/usr/share/doc/$pkgname
+}