[arch-commits] Commit in haskell-uri-bytestring/repos (2 files)

[Felix Yan]

    Date: Thursday, May 10, 2018 @ 06:14:34
  Author: felixonmars
Revision: 319945

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-uri-bytestring/repos/community-staging-x86_64/
  haskell-uri-bytestring/repos/community-staging-x86_64/PKGBUILD
    (from rev 319944, haskell-uri-bytestring/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-uri-bytestring/repos/community-staging-x86_64/PKGBUILD (from rev 319944, haskell-uri-bytestring/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-05-10 06:14:34 UTC (rev 319945)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=uri-bytestring
+pkgname=haskell-uri-bytestring
+pkgver=0.3.1.1
+pkgrel=11
+pkgdesc="Haskell URI parsing as ByteStrings"
+url="https://github.com/Soostone/uri-bytestring"
+license=('custom:BSD3')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-attoparsec' 'haskell-blaze-builder' 'haskell-th-lift-instances')
+makedepends=('ghc' 'haskell-hunit' 'haskell-quickcheck' 'haskell-tasty' 'haskell-tasty-hunit'
+             'haskell-tasty-quickcheck' 'haskell-base-compat' 'haskell-quickcheck-instances'
+             'haskell-semigroups' 'haskell-generics-sop')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('a2f154e74e3c74ecf8f5934fe5e917b4d7a7c0ab712ca86da41adebb3da9d7e723275a9fc220dce7d1d065855d217c9462aedabd8844731228e45e0ef7af1ccc')
+
+prepare() {
+    sed -i '/fail/d' ${_hkgname}-${pkgver}/${_hkgname}.cabal
+}
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-lib-Werror
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}