[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Thursday, May 10, 2018 @ 15:29:58
  Author: felixonmars
Revision: 320406

addpkg: python-pycryptodome 3.6.1-2

Added:
  python-pycryptodome/
  python-pycryptodome/repos/
  python-pycryptodome/trunk/
  python-pycryptodome/trunk/PKGBUILD

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Added: python-pycryptodome/trunk/PKGBUILD
===================================================================
--- python-pycryptodome/trunk/PKGBUILD	                        (rev 0)
+++ python-pycryptodome/trunk/PKGBUILD	2018-05-10 15:29:58 UTC (rev 320406)
@@ -0,0 +1,56 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Josip Ponjavic <josipponjavic at gmail dot com>
+
+pkgbase=python-pycryptodome
+pkgname=('python-pycryptodome' 'python2-pycryptodome')
+pkgver=3.6.1
+pkgrel=2
+license=('BSD')
+arch=('x86_64')
+url='http://www.pycryptodome.org/'
+makedepends=('gmp' 'python-setuptools' 'python2-setuptools')
+source=("pycryptodome-${pkgver}.tar.gz::https://github.com/Legrandin/pycryptodome/archive/v${pkgver}.tar.gz")
+sha512sums=('cd3644a31f9e3686b1eaf006001d5db509bb856d72d4f64b8cdf3aec9801e6eba4f2308d3c12fd3edc655153cddb02552f22f71b56121f84d4b3b376672f08af')
+
+prepare() {
+  cp -a "pycryptodome-$pkgver"{,-python2}
+}
+
+build() {
+  cd "$srcdir/pycryptodome-$pkgver"
+  python setup.py build
+
+  cd "$srcdir/pycryptodome-$pkgver-python2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/pycryptodome-$pkgver"
+  python setup.py test
+
+  cd "$srcdir/pycryptodome-$pkgver-python2"
+  python2 setup.py test
+}
+
+package_python-pycryptodome() {
+  pkgdesc="Collection of cryptographic algorithms and protocols, implemented for use from Python 3."
+  depends=('python' 'gmp')
+  conflicts=('python-crypto')
+  provides=('python-crypto')
+
+  cd "pycryptodome-$pkgver"
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+  install -Dm644 LICENSE.rst "$pkgdir/usr/share/licenses/$pkgname/LICENSE.rst"
+}
+
+package_python2-pycryptodome() {
+  pkgdesc="Collection of cryptographic algorithms and protocols, implemented for use from Python 2."
+  depends=('python2' 'gmp')
+  conflicts=('python2-crypto')
+  provides=('python2-crypto')
+
+  cd "pycryptodome-$pkgver-python2"
+  python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
+  install -Dm644 LICENSE.rst "$pkgdir/usr/share/licenses/$pkgname/LICENSE.rst"
+}


Property changes on: python-pycryptodome/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property