[arch-commits] Commit in cfitsio/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Thursday, May 10, 2018 @ 20:01:09
  Author: arojas
Revision: 323894

archrelease: copy trunk to staging-x86_64

Added:
  cfitsio/repos/staging-x86_64/
  cfitsio/repos/staging-x86_64/PKGBUILD
    (from rev 323893, cfitsio/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: cfitsio/repos/staging-x86_64/PKGBUILD (from rev 323893, cfitsio/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2018-05-10 20:01:09 UTC (rev 323894)
@@ -0,0 +1,40 @@
+# $Id$
+# Maintainer:
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Tobias Powalowski <tpowa at archlinux.org>
+
+pkgname=cfitsio
+pkgver=3.450
+pkgrel=1
+pkgdesc="A library of C and Fortran subroutines for reading and writing data files in FITS (Flexible Image Transport System) data format"
+arch=(x86_64)
+url="http://heasarc.gsfc.nasa.gov/fitsio/"
+license=(custom)
+depends=(curl)
+source=("ftp://heasarc.gsfc.nasa.gov/software/fitsio/c/${pkgname}${pkgver/./}.tar.gz")
+sha256sums=('bf6012dbe668ecb22c399c4b7b2814557ee282c74a7d5dc704eb17c30d9fb92e')
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --enable-reentrant
+  make shared
+  make utils
+}
+
+check() {
+  cd $pkgname
+  LD_LIBRARY_PATH=. ./testprog > testprog.lis
+  [[ -z $(diff testprog.lis testprog.out) ]] || return 1
+  [[ -z $(cmp testprog.fit testprog.std) ]] || return 1
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+
+  install -D -m644 License.txt \
+    "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+
+# Fix conflicts with ccfits and smem
+  rm "$pkgdir"/usr/bin/{cookbook,smem,testprog}
+}