[arch-commits] Commit in haskell-yesod/repos (2 files)

[Felix Yan]

    Date: Saturday, May 12, 2018 @ 18:13:45
  Author: felixonmars
Revision: 321170

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-yesod/repos/community-staging-x86_64/
  haskell-yesod/repos/community-staging-x86_64/PKGBUILD
    (from rev 321169, haskell-yesod/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-yesod/repos/community-staging-x86_64/PKGBUILD (from rev 321169, haskell-yesod/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-05-12 18:13:45 UTC (rev 321170)
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=yesod
+pkgname=haskell-yesod
+pkgver=1.4.5
+pkgrel=258
+pkgdesc="Creation of type-safe, RESTful web applications."
+url="http://www.yesodweb.com/"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' "haskell-aeson" "haskell-blaze-html" "haskell-blaze-markup"
+         "haskell-conduit-extra" "haskell-data-default-class" "haskell-fast-logger"
+         "haskell-monad-control" "haskell-monad-logger" "haskell-resourcet" "haskell-semigroups"
+         "haskell-shakespeare" "haskell-streaming-commons" "haskell-text"
+         "haskell-unordered-containers" "haskell-wai" "haskell-wai-extra" "haskell-wai-logger"
+         "haskell-warp" "haskell-yaml" "haskell-yesod-core" "haskell-yesod-form"
+         "haskell-yesod-persistent")
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha256sums=('267c8780b27cc0ae8199f80b3063683fb2cd62eeb9696c4b155a298fb035e6e9')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+    
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}