[arch-commits] Commit in tamarin-prover/repos (2 files)

[Felix Yan]

    Date: Monday, May 14, 2018 @ 07:53:45
  Author: felixonmars
Revision: 321833

archrelease: copy trunk to community-staging-x86_64

Added:
  tamarin-prover/repos/community-staging-x86_64/
  tamarin-prover/repos/community-staging-x86_64/PKGBUILD
    (from rev 321832, tamarin-prover/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: tamarin-prover/repos/community-staging-x86_64/PKGBUILD (from rev 321832, tamarin-prover/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-05-14 07:53:45 UTC (rev 321833)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=tamarin-prover
+pkgver=1.4.0
+pkgrel=7
+pkgdesc="The Tamarin prover for security protocol analysis"
+url="http://tamarin-prover.github.io"
+license=("GPL")
+arch=('x86_64')
+depends=('ghc-libs' 'graphviz' 'maude' 'haskell-hunit' 'haskell-binary-orphans'
+         'haskell-blaze-builder' 'haskell-blaze-html' 'haskell-cmdargs' 'haskell-conduit'
+         'haskell-fclabels' 'haskell-file-embed' 'haskell-gitrev' 'haskell-http-types'
+         'haskell-lifted-base' 'haskell-monad-unlift' 'haskell-mtl' 'haskell-parsec'
+         'haskell-resourcet' 'haskell-safe' 'haskell-shakespeare' 'haskell-text' 'haskell-threads'
+         'haskell-wai' 'haskell-warp' 'haskell-yesod-core' 'haskell-yesod-static'
+         'haskell-tamarin-prover-utils' 'haskell-tamarin-prover-term'
+         'haskell-tamarin-prover-theory')
+optdepends=('ocaml: for sapic support')
+makedepends=('ghc' 'ocaml')
+source=("tamarin-prover-$pkgver.tar.gz::https://github.com/tamarin-prover/tamarin-prover/archive/$pkgver.tar.gz")
+sha512sums=('7c1afe6a53b596c2ce01e9ad7a7f464af1f4efbc5f8edc13d5ec8bc32ce4e91ddde91dff6ab8e01cf3cf30a37a3a18953d937debc36c9df664f718d968e2ae74')
+
+prepare() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    sed -i '/cp sapic/d' plugins/sapic/Makefile
+}
+
+build() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-executable-dynamic --prefix=/usr \
+        --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" \
+            -fthreaded -ftest-coverage -f-build-tests
+    runhaskell Setup build
+
+    cd plugins/sapic
+    make -j1
+}
+
+package() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    runhaskell Setup copy --destdir="${pkgdir}"
+
+    install -Dm644 etc/filetype.vim "$pkgdir"/usr/share/vim/vimfiles/filetype.vim
+    install -Dm644 etc/spthy.vim "$pkgdir"/usr/share/vim/vimfiles/syntax/spthy.vim
+    install -Dm644 etc/sapic.vim "$pkgdir"/usr/share/vim/vimfiles/syntax/sapic.vim
+
+    cd plugins/sapic
+    install -Dm755 sapic "$pkgdir"/usr/bin/sapic
+}