[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Wednesday, May 16, 2018 @ 12:20:35
  Author: felixonmars
Revision: 322810

addpkg: python-mongoengine 0.15.1-1

Added:
  python-mongoengine/
  python-mongoengine/repos/
  python-mongoengine/trunk/
  python-mongoengine/trunk/PKGBUILD

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Added: python-mongoengine/trunk/PKGBUILD
===================================================================
--- python-mongoengine/trunk/PKGBUILD	                        (rev 0)
+++ python-mongoengine/trunk/PKGBUILD	2018-05-16 12:20:35 UTC (rev 322810)
@@ -0,0 +1,59 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Simon Sapin <simon dot sapin at exyr dot org>
+# Contributor: Kyle Keen <keenerd at gmail.com>
+
+pkgbase=python-mongoengine
+pkgname=(python-mongoengine python2-mongoengine)
+pkgver=0.15.1
+pkgrel=1
+pkgdesc="A Python Object-Document-Mapper for working with MongoDB"
+url="https://github.com/MongoEngine/mongoengine"
+license=('MIT')
+arch=('any')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-pymongo' 'python2-pymongo')
+checkdepends=('python-nose' 'python2-nose' 'python-coverage' 'python2-coverage'
+              'python-blinker' 'python2-blinker' 'python-pillow' 'python2-pillow' 'pifpaf' 'mongodb')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/MongoEngine/mongoengine/archive/v$pkgver.tar.gz")
+sha512sums=('0c9c0c389db03f285732a88e246b20abc1e7bec4fdad310fed879640a4ada3be50f6a08362e31b73ca648a7984b649c775c0c737045d5b08deb6d3849a1a8c29')
+
+prepare() {
+  sed -i 's/coverage==/coverage>=/' mongoengine-$pkgver/setup.py
+  cp -a mongoengine-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/mongoengine-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/mongoengine-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/mongoengine-$pkgver
+  pifpaf run mongodb --port 27017 python setup.py nosetests || warning "Tests failed"
+
+  cd "$srcdir"/mongoengine-$pkgver-py2
+  pifpaf run mongodb --port 27017 python2 setup.py nosetests || warning "Tests failed"
+}
+
+package_python-mongoengine() {
+  depends=('python-pymongo' 'python-six')
+  optdepends=('python-dateutil: for DateTimeField'
+              'python-pillow: for ImageField / ImageGridFsProxy')
+
+  cd mongoengine-$pkgver
+  python3 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-mongoengine() {
+  depends=('python2-pymongo' 'python2-six')
+  optdepends=('python2-dateutil: for DateTimeField'
+              'python2-pillow: for ImageField / ImageGridFsProxy')
+
+  cd mongoengine-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}


Property changes on: python-mongoengine/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property