[arch-commits] Commit in haskell-hspec-core/repos (2 files)

[Felix Yan]

    Date: Wednesday, May 16, 2018 @ 17:17:06
  Author: felixonmars
Revision: 323008

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hspec-core/repos/community-staging-x86_64/
  haskell-hspec-core/repos/community-staging-x86_64/PKGBUILD
    (from rev 323007, haskell-hspec-core/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-hspec-core/repos/community-staging-x86_64/PKGBUILD (from rev 323007, haskell-hspec-core/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-05-16 17:17:06 UTC (rev 323008)
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=hspec-core
+pkgname=haskell-hspec-core
+pkgver=2.5.0
+pkgrel=2
+pkgdesc="A Testing Framework for Haskell"
+url="http://hspec.github.io/"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ansi-terminal' 'haskell-call-stack' 'haskell-clock'
+         'haskell-hspec-expectations' 'haskell-hunit' 'haskell-quickcheck' 'haskell-quickcheck-io'
+         'haskell-random' 'haskell-setenv' 'haskell-tf-random')
+makedepends=('ghc' 'haskell-hspec-meta' 'haskell-silently' 'haskell-temporary')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('b5c299974b95b61d0644552d4d244f3aefe34990352ad7a67d2c7600e2d63acd11b7c3cae67b31a5dc00c76cfeb09afd27dfb1e170d33fdd1b0977258063f35d')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}