[arch-commits] Commit in (4 files)

[Eli Schwartz]

    Date: Wednesday, May 16, 2018 @ 19:53:49
  Author: eschwartz
Revision: 323186

Add new package required for devendoring pip

Added:
  python-progress/
  python-progress/repos/
  python-progress/trunk/
  python-progress/trunk/PKGBUILD

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Added: python-progress/trunk/PKGBUILD
===================================================================
--- python-progress/trunk/PKGBUILD	                        (rev 0)
+++ python-progress/trunk/PKGBUILD	2018-05-16 19:53:49 UTC (rev 323186)
@@ -0,0 +1,39 @@
+# $Id$
+# Maintainer: Eli Schwartz <eschwartz at archlinux.org>
+# Contributor: Guillaume Brogi <gui-gui at netcourrier dot com>
+
+_pkgname=progress
+pkgbase=python-progress
+pkgname=('python-progress' 'python2-progress')
+pkgver=1.3
+pkgrel=2
+pkgdesc="Easy to use progress bars for Python"
+arch=('any')
+url="https://github.com/verigak/${_pkgname}"
+license=('ISC')
+makedepends=('python-setuptools' 'python2-setuptools')
+source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/${pkgver}.tar.gz")
+sha256sums=('f0294eca56eed70f3459e434e8fe4c223a677bdfea6a28a97740f91a86130c43')
+
+build() {
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+
+    python setup.py build
+    python2 setup.py build
+}
+
+package_python-progress() {
+    depends=('python')
+
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+    python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+	install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}
+
+package_python2-progress() {
+    depends=('python2')
+
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+    python2 setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+	install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}


Property changes on: python-progress/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property