[arch-commits] Commit in python-toml/repos (community-any community-any/PKGBUILD)

[Eli Schwartz]

    Date: Wednesday, May 16, 2018 @ 20:30:31
  Author: eschwartz
Revision: 323231

archrelease: copy trunk to community-any

Added:
  python-toml/repos/community-any/
  python-toml/repos/community-any/PKGBUILD
    (from rev 323230, python-toml/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: python-toml/repos/community-any/PKGBUILD (from rev 323230, python-toml/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2018-05-16 20:30:31 UTC (rev 323231)
@@ -0,0 +1,49 @@
+# $Id$
+# Maintainer: Eli Schwartz <eschwartz at archlinux.org>
+# Contributor: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Artem Vorotnikov <artem at vorotnikov.me>
+# Contributor: Andy Weidenbaum <archbaum at gmail.com>
+
+_pkgname=pytoml
+pkgbase=python-pytoml
+pkgname=('python-pytoml' 'python2-pytoml')
+pkgver=0.1.14
+pkgrel=2
+pkgdesc="A TOML-0.4.0 parser/writer for Python."
+arch=('any')
+url="https://github.com/avakar/${_pkgname}"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-pytest' 'python2-pytest')
+source=("${_pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
+sha256sums=('ced2c5d5c240fa96adf2ccbdfa071d51cc80415dd11a4ea800ff0ec987459d34')
+
+build() {
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+
+    python setup.py build
+    python2 setup.py build
+}
+
+check() {
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+
+    python -m pytest
+    python2 -m pytest
+}
+
+package_python-pytoml() {
+    depends=('python')
+
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+    python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+    install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}
+
+package_python2-pytoml() {
+    depends=('python2')
+
+    cd "${srcdir}"/${_pkgname}-${pkgver}
+    python2 setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+    install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}