[arch-commits] Commit in oxygen/repos (2 files)
Antonio Rojas
arojas at archlinux.org
Fri May 18 15:37:08 UTC 2018
Date: Friday, May 18, 2018 @ 15:37:08
Author: arojas
Revision: 324527
archrelease: copy kde-unstable to kde-unstable-x86_64
Added:
oxygen/repos/kde-unstable-x86_64/
oxygen/repos/kde-unstable-x86_64/PKGBUILD
(from rev 324526, oxygen/kde-unstable/PKGBUILD)
----------+
PKGBUILD | 64 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 64 insertions(+)
Copied: oxygen/repos/kde-unstable-x86_64/PKGBUILD (from rev 324526, oxygen/kde-unstable/PKGBUILD)
===================================================================
--- kde-unstable-x86_64/PKGBUILD (rev 0)
+++ kde-unstable-x86_64/PKGBUILD 2018-05-18 15:37:08 UTC (rev 324527)
@@ -0,0 +1,64 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgbase=oxygen
+pkgname=(oxygen oxygen-kde4)
+pkgver=5.12.90
+pkgrel=1
+arch=(x86_64)
+url='https://www.kde.org/workspaces/plasmadesktop/'
+license=(LGPL)
+makedepends=(frameworkintegration kcmutils kdecoration extra-cmake-modules kdoctools kdelibs automoc4 kwayland)
+source=("https://download.kde.org/unstable/plasma/$pkgver/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('72a2fbaafd1a5a7b595a18b35ac3dcb39238b1a1df836f2b87aa5ce1d7f3fccc'
+ 'SKIP')
+validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E' # Jonathan Riddell
+ '0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D' # Bhushan Shah <bshah at kde.org>
+ 'D07BD8662C56CB291B316EB2F5675605C74E02CF' # David Edmundson
+ '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart at gmail.com>
+
+prepare() {
+ mkdir -p build{,-kde4}
+}
+
+build() {
+ cd build
+ cmake ../$pkgname-$pkgver \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=lib \
+ -DBUILD_TESTING=OFF
+ make
+ cd ..
+
+ cd build-kde4
+ cmake ../$pkgname-$pkgver \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DBUILD_TESTING=OFF \
+ -DUSE_KDE4=ON
+ make
+}
+
+package_oxygen() {
+ pkgdesc='KDE Oxygen style'
+ depends=(frameworkintegration kdecoration kcmutils kwayland hicolor-icon-theme)
+ conflicts=(oxygen-cursors)
+ replaces=(oxygen-cursors)
+ groups=(plasma)
+
+ cd build
+ make DESTDIR="$pkgdir" install
+}
+
+package_oxygen-kde4() {
+ pkgdesc='KDE Oxygen style for KDE4 applications'
+ depends=(kdelibs)
+
+ cd build-kde4
+ make DESTDIR="$pkgdir" install
+
+ # needed so that pure Qt4 apps are correctly themed
+ install -d -m755 "$pkgdir"/usr/lib/qt4/plugins/styles
+ ln -s /usr/lib/kde4/plugins/styles/oxygen.so "$pkgdir"/usr/lib/qt4/plugins/styles
+}
More information about the arch-commits
mailing list