[arch-commits] Commit in plasma-workspace/repos (3 files)

[Antonio Rojas]

    Date: Friday, May 18, 2018 @ 15:39:09
  Author: arojas
Revision: 324534

archrelease: copy kde-unstable to kde-unstable-x86_64

Added:
  plasma-workspace/repos/kde-unstable-x86_64/
  plasma-workspace/repos/kde-unstable-x86_64/PKGBUILD
    (from rev 324533, plasma-workspace/kde-unstable/PKGBUILD)
  plasma-workspace/repos/kde-unstable-x86_64/kde.pam
    (from rev 324533, plasma-workspace/kde-unstable/kde.pam)

----------+
 PKGBUILD |   71 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 kde.pam  |    9 +++++++
 2 files changed, 80 insertions(+)

Copied: plasma-workspace/repos/kde-unstable-x86_64/PKGBUILD (from rev 324533, plasma-workspace/kde-unstable/PKGBUILD)
===================================================================
--- kde-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ kde-unstable-x86_64/PKGBUILD	2018-05-18 15:39:09 UTC (rev 324534)
@@ -0,0 +1,71 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Alexey D. <lq07829icatm at rambler.ru>
+
+pkgbase=plasma-workspace
+pkgname=(plasma-workspace plasma-wayland-session)
+pkgver=5.12.90
+pkgrel=1
+pkgdesc='KDE Plasma Workspace'
+arch=(x86_64)
+url='https://www.kde.org/workspaces/plasmadesktop/'
+license=(LGPL)
+depends=(kjsembed knotifyconfig libksysguard ktexteditor libqalculate qt5-tools kde-cli-tools bc
+         xorg-xrdb xorg-xsetroot kactivitymanagerd kholidays xorg-xmessage xorg-xprop milou prison kwin
+         plasma-integration kdelibs4support)
+makedepends=(extra-cmake-modules kdoctools gpsd baloo appstream-qt krunner networkmanager-qt kdesignerplugin python)
+groups=(plasma)
+source=("https://download.kde.org/unstable/plasma/$pkgver/$pkgbase-$pkgver.tar.xz"{,.sig} kde.pam)
+sha256sums=('b58f8eca82de3da6dbafbc7b1e7807c8f44096b68ae2f0c017dd9a3b9010feb3'
+            'SKIP'
+            '00090291204baabe9d6857d3b1419832376dd2e279087d718b64792691e86739')
+validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E'  # Jonathan Riddell
+              '0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D'  # Bhushan Shah <bshah at kde.org>
+              'D07BD8662C56CB291B316EB2F5675605C74E02CF'  # David Edmundson
+              '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart at gmail.com>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgbase-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DCMAKE_INSTALL_LIBEXECDIR=lib \
+    -DBUILD_TESTING=OFF
+  make
+}
+
+package_plasma-workspace() {
+  optdepends=('plasma-workspace-wallpapers: additional wallpapers'
+              'gpsd: GPS based geolocation' 'networkmanager-qt: IP based geolocation'
+              'kdepim-addons: displaying PIM events in the calendar'
+              'appmenu-qt4: global menu support for Qt4 applications'
+              'qt5-virtualkeyboard: virtual keyboard support in lock screen'
+              'baloo: Baloo search runner'
+              'appstream-qt: package search runner')
+  conflicts=(kuiserver)
+  provides=(kuiserver notification-daemon)
+  replaces=(kuiserver)
+  backup=('etc/pam.d/kde')
+
+  cd build
+  make DESTDIR="$pkgdir" install
+
+  install -Dm644 "$srcdir"/kde.pam "$pkgdir"/etc/pam.d/kde
+
+  # Split plasma-wayland scripts
+  rm -r "$pkgdir"/usr/share/wayland-sessions
+}
+
+package_plasma-wayland-session() {
+  pkgdesc='Plasma Wayland session'
+  depends=(plasma-workspace qt5-wayland kwayland-integration xorg-server-xwayland)
+  groups=()
+
+  install -Dm644 build/plasmawayland.desktop "$pkgdir"/usr/share/wayland-sessions/plasmawayland.desktop
+}

Copied: plasma-workspace/repos/kde-unstable-x86_64/kde.pam (from rev 324533, plasma-workspace/kde-unstable/kde.pam)
===================================================================
--- kde-unstable-x86_64/kde.pam	                        (rev 0)
+++ kde-unstable-x86_64/kde.pam	2018-05-18 15:39:09 UTC (rev 324534)
@@ -0,0 +1,9 @@
+#%PAM-1.0
+
+auth            include         system-login
+
+account         include         system-login
+
+password        include         system-login
+
+session         include         system-login