[arch-commits] Commit in python-logbook/repos (2 files)

[Felix Yan]

    Date: Saturday, May 19, 2018 @ 11:05:08
  Author: felixonmars
Revision: 324526

archrelease: copy trunk to community-testing-x86_64

Added:
  python-logbook/repos/community-testing-x86_64/
  python-logbook/repos/community-testing-x86_64/PKGBUILD
    (from rev 324525, python-logbook/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: python-logbook/repos/community-testing-x86_64/PKGBUILD (from rev 324525, python-logbook/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2018-05-19 11:05:08 UTC (rev 324526)
@@ -0,0 +1,57 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Tomas Schertel<tschertel at gmail.com>
+
+pkgbase=python-logbook
+pkgname=(python-logbook python2-logbook)
+pkgver=1.4.0
+pkgrel=1
+pkgdesc="Logging sytem for Python that replaces the standard library’s logging module"
+arch=('x86_64')
+url="http://packages.python.org/Logbook/index.html"
+license=('BSD')
+makedepends=('python-setuptools' 'python2-setuptools' 'cython' 'cython2' 'python-six' 'python2-six')
+checkdepends=('redis' 'python-pytest' 'python2-pytest' 'python-sqlalchemy' 'python2-sqlalchemy'
+              'python-mock' 'python2-mock' 'python-redis' 'python2-redis' 'python-pyzmq'
+              'python2-pyzmq' 'python-execnet' 'python2-execnet' 'python-jinja' 'python2-jinja'
+              'python-brotli' 'python2-brotli' 'python-pifpaf')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/mitsuhiko/logbook/archive/$pkgver.tar.gz")
+sha512sums=('3ea969e9e2075e34a915566be906266b408671657e4cecbe47663c28f2212c0522b0f0eb2832fbc4fb906f70c8e53d3cdbe65923dafe53a77545b8126ab539f2')
+
+prepare() {
+  cp -a logbook-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/logbook-$pkgver
+  cython logbook/_speedups.pyx
+  python setup.py build
+
+  cd "$srcdir"/logbook-$pkgver-py2
+  cython2 logbook/_speedups.pyx
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/logbook-$pkgver
+  LC_CTYPE=en_US.UTF-8 pifpaf run redis py.test tests
+
+  cd "$srcdir"/logbook-$pkgver-py2
+  LC_CTYPE=en_US.UTF-8 pifpaf run redis py.test2 tests
+}
+
+package_python-logbook() {
+  depends=('python-six')
+
+  cd logbook-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm664 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-logbook() {
+  depends=('python2-six')
+
+  cd logbook-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm664 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}