[arch-commits] Commit in (4 files)

[Bruno Pagani]

    Date: Wednesday, May 23, 2018 @ 17:15:35
  Author: archange
Revision: 328377

Initial addition of python-cftime to [community]

Added:
  python-cftime/
  python-cftime/repos/
  python-cftime/trunk/
  python-cftime/trunk/PKGBUILD

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Added: python-cftime/trunk/PKGBUILD
===================================================================
--- python-cftime/trunk/PKGBUILD	                        (rev 0)
+++ python-cftime/trunk/PKGBUILD	2018-05-23 17:15:35 UTC (rev 328377)
@@ -0,0 +1,44 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkg=cftime
+pkgbase=python-${_pkg,,}
+pkgname=("python-${_pkg,,}" "python2-${_pkg,,}")
+pkgver=1.0.0
+pkgrel=1
+pkgdesc="Time-handling functionality from python-netcdf4"
+arch=('x86_64')
+url="https://unidata.github.io/cftime"
+license=('MIT')
+makedepends=('cython' 'python-setuptools' 'cython2' 'python2-setuptools' 'python-numpy' 'python2-numpy')
+source=("https://pypi.io/packages/source/c/${_pkg}/${_pkg}-${pkgver}.tar.gz")
+sha256sums=('f62fe79ed2ad38f4211477e59f6f045c91278351f4ce7578e33ddf52fb121ea8')
+
+prepare() {
+    cp -a ${_pkg}-${pkgver}{,-py2}
+}
+
+build() {
+    cd ${_pkg}-${pkgver}
+    python setup.py build
+
+    cd ../${_pkg}-${pkgver}-py2
+    python2 setup.py build
+}
+
+package_python-cftime() {
+    depends=('python-numpy')
+
+    cd ${_pkg}-${pkgver}
+    python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
+
+    install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}
+
+package_python2-cftime() {
+    depends=('python2-numpy')
+
+    cd ${_pkg}-${pkgver}-py2
+    python2 setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
+
+    install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}