[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Wednesday, May 23, 2018 @ 21:32:56
  Author: felixonmars
Revision: 328475

addpkg: python-aniso8601 3.0.0-1

Added:
  python-aniso8601/
  python-aniso8601/repos/
  python-aniso8601/trunk/
  python-aniso8601/trunk/PKGBUILD

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Added: python-aniso8601/trunk/PKGBUILD
===================================================================
--- python-aniso8601/trunk/PKGBUILD	                        (rev 0)
+++ python-aniso8601/trunk/PKGBUILD	2018-05-23 21:32:56 UTC (rev 328475)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-aniso8601
+pkgname=(python-aniso8601 python2-aniso8601)
+pkgver=3.0.0
+pkgrel=1
+pkgdesc="A library for parsing ISO 8601 strings."
+url="https://bitbucket.org/nielsenb/aniso8601"
+license=('BSD')
+arch=('any')
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner' 'python-dateutil' 'python2-dateutil')
+source=("$pkgbase-$pkgver.tar.gz::https://bitbucket.org/nielsenb/aniso8601/get/v$pkgver.tar.gz")
+sha512sums=('6d8d3958a83cbd5981e0f01256fd5b6f666c280617caee655303581836f75e8bf552fa1706da678cc028e7f4ec9a239fd1c72d0650debeb53f06fad5b8624d31')
+
+prepare() {
+  mv nielsenb-aniso8601-* aniso8601-$pkgver
+  cp -a aniso8601-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/aniso8601-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/aniso8601-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/aniso8601-$pkgver
+  python setup.py pytest
+
+  cd "$srcdir"/aniso8601-$pkgver-py2
+  python2 setup.py pytest
+}
+
+package_python-aniso8601() {
+  depends=('python')
+
+  cd aniso8601-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-aniso8601() {
+  depends=('python2')
+
+  cd aniso8601-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}


Property changes on: python-aniso8601/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property