[arch-commits] Commit in darcs/repos (2 files)

[Felix Yan]

    Date: Thursday, May 24, 2018 @ 20:08:27
  Author: felixonmars
Revision: 329088

archrelease: copy trunk to community-staging-x86_64

Added:
  darcs/repos/community-staging-x86_64/
  darcs/repos/community-staging-x86_64/PKGBUILD
    (from rev 329087, darcs/trunk/PKGBUILD)

----------+
 PKGBUILD |   67 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)

Copied: darcs/repos/community-staging-x86_64/PKGBUILD (from rev 329087, darcs/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-05-24 20:08:27 UTC (rev 329088)
@@ -0,0 +1,67 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=darcs
+pkgver=2.14.0
+pkgrel=25
+pkgdesc="A distributed, interactive, smart revision control system"
+url="http://darcs.net"
+license=("GPL2")
+arch=('x86_64')
+depends=('curl' 'ghc-libs' 'haskell-async' 'haskell-attoparsec' 'haskell-base16-bytestring'
+         'haskell-cryptohash' 'haskell-data-ordlist' 'haskell-fgl' 'haskell-graphviz'
+         'haskell-hashable' 'haskell-html' 'haskell-http' 'haskell-knob' 'haskell-mmap'
+         'haskell-network' 'haskell-network-uri' 'haskell-old-time'
+         'haskell-sandi' 'haskell-random' 'haskell-regex-applicative' 'haskell-regex-compat-tdfa'
+         'haskell-tar' 'haskell-unix-compat' 'haskell-utf8-string'
+         'haskell-vector' 'haskell-zip-archive' 'haskell-zlib')
+makedepends=('ghc' 'haskell-cmdargs' 'haskell-findbin' 'haskell-hunit' 'haskell-quickcheck'
+             'haskell-shelly' 'haskell-split' 'haskell-test-framework'
+             'haskell-test-framework-hunit' 'haskell-test-framework-quickcheck2')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('a9c90b4d1a5caa395682405123702452a45382771795a5bd5c8d1a6816ca4411ca0bebc9188e9b396774e7db75289c73de9630dac388070d140ce20e7537fd46')
+
+prepare() {
+    cd $pkgname-$pkgver
+    sed -i -e 's/shelly       >= 1.6.8 && < 1.7,/shelly       >= 1.6.8,/' \
+           -e 's/<.*2.11/<3/' -e 's/<.*2.2/<3/' -e 's/<.*2999.20/<3000/' \
+           -e 's/<.*5.6/<6/' $pkgname.cabal
+
+    sed -e 's/^ghc /ghc -dynamic /' \
+        -e 's/ ghc / ghc -dynamic /' \
+        -i tests/*.sh tests/lib
+}
+
+build() {
+    cd $pkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+        -fcurl -fpkgconfig -f-static -fterminfo -fthreaded -fexecutable \
+        -f-rts -foptimize -f-warn-as-error -f-libiconv
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $pkgname-$pkgver
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+    chmod 644 "${pkgdir}/usr/share/man/man1/darcs.1"
+
+    install -Dm644 contrib/darcs_completion "${pkgdir}/usr/share/bash-completion/completions/darcs"
+    install -Dm644 contrib/_darcs.zsh "${pkgdir}/usr/share/zsh/site-functions/_darcs"
+}