[arch-commits] Commit in (kakoune kakoune/repos kakoune/trunk kakoune/trunk/PKGBUILD)

[Morten Linderud]

    Date: Friday, May 25, 2018 @ 16:59:40
  Author: foxboron
Revision: 329435

Added kakoune to community

Added:
  kakoune/
  kakoune/repos/
  kakoune/trunk/
  kakoune/trunk/PKGBUILD

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Added: kakoune/trunk/PKGBUILD
===================================================================
--- kakoune/trunk/PKGBUILD	                        (rev 0)
+++ kakoune/trunk/PKGBUILD	2018-05-25 16:59:40 UTC (rev 329435)
@@ -0,0 +1,39 @@
+# Maintainer: Morten Linderud <foxboron at archlinux.org>
+# Contributor: Frank Lenormand <lenormf at gmail dot com>
+pkgname=kakoune
+pkgver=2018.04.13
+pkgrel=2
+pkgdesc="Multiple-selection, UNIX-flavored modal editor"
+arch=("x86_64")
+url="http://kakoune.org/"
+license=("custom:unlicense")
+depends=("ncurses")
+optdepends=(
+    "file: MIME-type based file format detection"
+    "aspell: spell checking support"
+    "clang: C/C++ completion and diagnostics support"
+    "ranger: filesystem explorer"
+    "tmux: splitting and creating windows"
+#    "universal-ctags-git: provides \`readtags\` used to jump to a symbol's definition"
+    "xdotool: X11 utility to focus arbitrary kakoune clients"
+    "xorg-xmessage: display debug messages in a new window"
+)
+makedepends=("asciidoc")
+source=("$pkgname-$pkgver.tar.gz::https://github.com/mawww/kakoune/archive/v${pkgver}.tar.gz")
+sha256sums=("dfbaf87479ae30fd87426ae1b5f6cbe4382d6fe17b64a0c58d9475bf038e50dc")
+
+build() {
+    cd "${pkgname}-${pkgver}/src"
+    make debug=no
+}
+
+check() {
+    cd "${pkgname}-${pkgver}/src"
+    make debug=no test
+}
+
+package() {
+    cd "${pkgname}-${pkgver}/src"
+    make debug=no install-strip DESTDIR="${pkgdir}" PREFIX=/usr
+    install -D ../UNLICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}