[arch-commits] Commit in haskell-hasql/repos (2 files)

[Felix Yan]

    Date: Saturday, May 26, 2018 @ 21:16:11
  Author: felixonmars
Revision: 331206

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hasql/repos/community-staging-x86_64/
  haskell-hasql/repos/community-staging-x86_64/PKGBUILD
    (from rev 331205, haskell-hasql/trunk/PKGBUILD)

----------+
 PKGBUILD |   68 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)

Copied: haskell-hasql/repos/community-staging-x86_64/PKGBUILD (from rev 331205, haskell-hasql/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-05-26 21:16:11 UTC (rev 331206)
@@ -0,0 +1,68 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Thomas Dziedzic <gostrc at gmail.com>
+
+_hkgname=hasql
+pkgname=haskell-hasql
+pkgver=1.1.1
+pkgrel=75
+pkgdesc="An efficient PostgreSQL driver and a flexible mapping API"
+url="https://github.com/nikita-volkov/hasql"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-attoparsec' 'haskell-base-prelude' 'haskell-bytestring-strict-builder'
+         'haskell-contravariant' 'haskell-contravariant-extras' 'haskell-data-default-class'
+         'haskell-dlist' 'haskell-hashable' 'haskell-hashtables' 'haskell-loch-th'
+         'haskell-placeholders' 'haskell-postgresql-binary' 'haskell-postgresql-libpq'
+         'haskell-profunctors' 'haskell-vector')
+makedepends=('ghc' 'haskell-bug' 'haskell-tasty' 'haskell-tasty-quickcheck' 'haskell-tasty-hunit'
+             'haskell-quickcheck-instances' 'haskell-quickcheck' 'haskell-rerebase')
+checkdepends=('postgresql' 'pifpaf')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('f72097118dbecd87c31394be882aa81a591d5e6d429bbee974cc4d6acaf1a86b9cb1c623666f3ffcc4f258992a3522d1780fbcc5a2edaded18c106bbe1fd28be')
+
+prepare() {
+    sed -e 's/tasty-hunit >= 0.9 && < 0.10,/tasty-hunit >= 0.9,/' \
+        -e 's/tasty >= 0.12 && < 0.13,/tasty >= 0.12,/' \
+        -e 's/tasty-quickcheck >= 0.9 && < 0.10,/tasty-quickcheck >= 0.9,/' \
+        -e '/semigroups/d' \
+        -i $_hkgname-$pkgver/$_hkgname.cabal
+    sed -e 's/deriving (Monoid)/deriving (Semigroup, Monoid)/' \
+        -e '/instance Semigroup/d' \
+        -i $_hkgname-$pkgver/library/Hasql/Private/Commands.hs
+    sed -e 's/ Monoid)/ Semigroup, Monoid)/' \
+        -e '/instance Semigroup/d' \
+        -i $_hkgname-$pkgver/library/Hasql/Private/Encoders/Params.hs
+}
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+
+    eval $(pifpaf run postgresql --host 127.0.0.1 --port 5432)
+    createuser -s postgres
+    runhaskell Setup test
+    pifpaf_stop
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}