[arch-commits] Commit in haskell-gtk/repos (2 files)

[Felix Yan]

    Date: Sunday, May 27, 2018 @ 15:08:32
  Author: felixonmars
Revision: 331897

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-gtk/repos/community-staging-x86_64/
  haskell-gtk/repos/community-staging-x86_64/PKGBUILD
    (from rev 331896, haskell-gtk/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: haskell-gtk/repos/community-staging-x86_64/PKGBUILD (from rev 331896, haskell-gtk/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-05-27 15:08:32 UTC (rev 331897)
@@ -0,0 +1,38 @@
+# $Id$
+# Maintainer: Sergej Pupykin <pupykin.s+arch at gmail.com>
+
+pkgname=haskell-gtk
+pkgver=0.14.9
+pkgrel=2
+pkgdesc="Binding to the gtk library for Gtk2Hs."
+url="https://hackage.haskell.org/package/gtk3"
+license=('LGPL2.1')
+arch=('x86_64')
+depends=('ghc-libs' 'gtk3' 'haskell-pango')
+makedepends=('ghc' 'haskell-gtk2hs-buildtools')
+provides=('gtk2hs-gtk')
+replaces=('gtk2hs-gtk')
+conflicts=('gtk2hs-gtk')
+source=("https://hackage.haskell.org/packages/archive/gtk3/${pkgver}/gtk3-${pkgver}.tar.gz")
+sha512sums=('aaf2a257c74f5b0a569d0e61aef535e2f0c8158feb34bed523c7aff31cf155098f93d3a88ba49bea906ae669bf63fb0486f4c747a620c2199c2e7859486e7270')
+
+build() {
+    cd "${srcdir}/gtk3-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd "${srcdir}/gtk3-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+}