[arch-commits] Commit in mkvtoolnix/repos (staging-x86_64 staging-x86_64/PKGBUILD)
Evangelos Foutras
foutrelis at archlinux.org
Thu May 31 01:36:19 UTC 2018
Date: Thursday, May 31, 2018 @ 01:36:18
Author: foutrelis
Revision: 325277
archrelease: copy trunk to staging-x86_64
Added:
mkvtoolnix/repos/staging-x86_64/
mkvtoolnix/repos/staging-x86_64/PKGBUILD
(from rev 325276, mkvtoolnix/trunk/PKGBUILD)
----------+
PKGBUILD | 60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 60 insertions(+)
Copied: mkvtoolnix/repos/staging-x86_64/PKGBUILD (from rev 325276, mkvtoolnix/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2018-05-31 01:36:18 UTC (rev 325277)
@@ -0,0 +1,60 @@
+# $Id$
+# Maintainer: Giovanni Scafora <giovanni at archlinux.org>
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: xduugu <xduugu at gmx.com>
+
+pkgbase=mkvtoolnix
+pkgname=('mkvtoolnix-cli' 'mkvtoolnix-gui')
+pkgver=23.0.0
+pkgrel=2
+pkgdesc='Set of tools to create, edit and inspect Matroska files'
+arch=('x86_64')
+url='https://www.bunkus.org/videotools/mkvtoolnix/'
+license=('GPL')
+makedepends=('boost' 'boost-libs' 'cmark' 'docbook-xsl' 'file' 'flac' 'libebml'
+ 'libmatroska' 'libogg' 'libvorbis' 'qt5-multimedia' 'ruby-rake'
+ 'zlib')
+source=("http://www.bunkus.org/videotools/mkvtoolnix/sources/mkvtoolnix-${pkgver}.tar.xz")
+sha256sums=('1da0b0cca24f6d45ef614e864bbec0043af0b53062f86a524fe799cc355c1d68')
+
+build() {
+ cd mkvtoolnix-${pkgver}
+
+ ./configure \
+ --prefix='/usr' \
+ --disable-qt
+ rake apps:mkvinfo $MAKEFLAGS
+ mv src/mkvinfo{,-cli}
+
+ ./configure \
+ --prefix='/usr' \
+ --disable-update-check
+ rake $MAKEFLAGS
+}
+
+package_mkvtoolnix-cli() {
+ depends=('boost-libs' 'file' 'flac' 'gcc-libs' 'glibc' 'libogg' 'zlib'
+ 'libebml.so' 'libmatroska.so' 'libvorbis.so')
+
+ cd mkvtoolnix-${pkgver}
+
+ rake DESTDIR="${pkgdir}" install
+ install -m 755 src/mkvinfo-cli "${pkgdir}"/usr/bin/mkvinfo
+ rm -rf "${pkgdir}"/usr/share/{applications,icons,mime,mkvtoolnix}
+ find "${pkgdir}" -name mkvtoolnix-gui* -delete
+}
+
+package_mkvtoolnix-gui() {
+ depends=('cmark' 'hicolor-icon-theme' 'mkvtoolnix-cli' 'qt5-base'
+ 'qt5-multimedia')
+
+ cd mkvtoolnix-${pkgver}
+
+ rake DESTDIR="${pkgdir}" install
+ rm -rf "${pkgdir}"/usr/share/locale
+ for t in mkv{extract,info,merge,propedit}; do
+ find "${pkgdir}" -name $t* -delete
+ done
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list