[arch-commits] Commit in haskell-incremental-parser/repos (2 files)

[Felix Yan]

    Date: Thursday, May 31, 2018 @ 03:46:50
  Author: felixonmars
Revision: 334041

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-incremental-parser/repos/community-staging-x86_64/
  haskell-incremental-parser/repos/community-staging-x86_64/PKGBUILD
    (from rev 334040, haskell-incremental-parser/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: haskell-incremental-parser/repos/community-staging-x86_64/PKGBUILD (from rev 334040, haskell-incremental-parser/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-05-31 03:46:50 UTC (rev 334041)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Thomas Dziedzic <gostrc at gmail.com>
+
+_hkgname=incremental-parser
+pkgname=haskell-incremental-parser
+pkgver=0.3.1.1
+pkgrel=11
+pkgdesc="Generic parser library capable of providing partial results from partial input."
+url="https://hackage.haskell.org/package/${_hkgname}"
+license=('GPL')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-monoid-subclasses')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-checkers' 'haskell-tasty'
+             'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('a614d294b868f1305f55d2d8a2987e444a7f2b4ac001024e9413d83146c729d2afed93a40f99e77430d5b8be5a9464800f533f85a17c7471ba8c970d7e94aac1')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE.txt"
+}