[arch-commits] Commit in mpd/repos/extra-x86_64 (8 files)
Gaëtan Bisson
bisson at archlinux.org
Thu Nov 1 01:33:23 UTC 2018
Date: Thursday, November 1, 2018 @ 01:33:22
Author: bisson
Revision: 337663
archrelease: copy trunk to extra-x86_64
Added:
mpd/repos/extra-x86_64/PKGBUILD
(from rev 337662, mpd/trunk/PKGBUILD)
mpd/repos/extra-x86_64/conf
(from rev 337662, mpd/trunk/conf)
mpd/repos/extra-x86_64/sysusers.d
(from rev 337662, mpd/trunk/sysusers.d)
mpd/repos/extra-x86_64/tmpfiles.d
(from rev 337662, mpd/trunk/tmpfiles.d)
Deleted:
mpd/repos/extra-x86_64/PKGBUILD
mpd/repos/extra-x86_64/conf
mpd/repos/extra-x86_64/sysusers.d
mpd/repos/extra-x86_64/tmpfiles.d
------------+
PKGBUILD | 131 +++++++++++++++++++++++++++++++----------------------------
conf | 12 ++---
sysusers.d | 4 -
tmpfiles.d | 6 +-
4 files changed, 81 insertions(+), 72 deletions(-)
Deleted: PKGBUILD
===================================================================
--- PKGBUILD 2018-11-01 01:32:05 UTC (rev 337662)
+++ PKGBUILD 2018-11-01 01:33:22 UTC (rev 337663)
@@ -1,61 +0,0 @@
-# Maintainer: Gaetan Bisson <bisson at archlinux.org>
-# Contributor: Angel Velasquez <angvp at archlinux.org>
-# Contributor: Andrea Scarpino <andrea at archlinux.org>
-# Contributor: Damir Perisa <damir.perisa at bluewin.ch>
-# Contributor: Ben <ben at benmazer.net>
-
-pkgname=mpd
-pkgver=0.20.23
-pkgrel=1
-pkgdesc='Flexible, powerful, server-side application for playing music'
-url='https://www.musicpd.org/'
-license=('GPL')
-arch=('x86_64')
-depends=('libao' 'ffmpeg' 'libmodplug' 'audiofile' 'libshout' 'libmad' 'curl'
- 'faad2' 'sqlite' 'jack' 'libmms' 'wavpack' 'avahi' 'libid3tag' 'yajl'
- 'libmpdclient' 'icu' 'libupnp' 'libnfs' 'libsamplerate' 'libsoxr'
- 'smbclient' 'libgme' 'zziplib' 'libsystemd')
-makedepends=('boost' 'doxygen')
-validpgpkeys=('0392335A78083894A4301C43236E8A58C6DB4512')
-#source=("https://www.musicpd.org/download/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.xz"{,.sig}
-source=("https://www.musicpd.org/download/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz"{,.sig}
- 'tmpfiles.d'
- 'sysusers.d'
- 'conf')
-sha256sums=('503e5f9f237290f568ff7956ab2f9aed563594bf749f19b8fe994fb21434afea'
- 'SKIP'
- '2faa85c12449a5b3ca422ff1c1fa06d057c7e262a74bfa6298c914a92d6f2e7a'
- '0b74c6e5db08daab3091dc15a6b0c75210ba2f9e98fa074f6cfd605a461056b6'
- 'f40f68205834ca53cea3372e930bfe6c2f9ecc9df3b1605df2fec63a658b2e03')
-
-backup=('etc/mpd.conf')
-
-build() {
- cd "${srcdir}/${pkgname}-${pkgver}"
- ./configure \
- --prefix=/usr \
- --sysconfdir=/etc \
- --enable-jack \
- --enable-libmpdclient \
- --enable-pipe-output \
- --enable-pulse \
- --enable-soundcloud \
- --enable-zzip \
- --disable-sidplay \
- --enable-systemd-daemon \
- --with-systemduserunitdir=/usr/lib/systemd/user \
- --with-systemdsystemunitdir=/usr/lib/systemd/system \
-
- make
-}
-
-package() {
- cd "${srcdir}/${pkgname}-${pkgver}"
- make DESTDIR="${pkgdir}" install
- install -Dm644 ../conf "${pkgdir}"/etc/mpd.conf
- install -Dm644 ../tmpfiles.d "${pkgdir}"/usr/lib/tmpfiles.d/mpd.conf
- install -Dm644 ../sysusers.d "${pkgdir}"/usr/lib/sysusers.d/mpd.conf
-
- sed '/\[Service\]/a User=mpd' -i "${pkgdir}"/usr/lib/systemd/system/mpd.service
- sed '/WantedBy=/c WantedBy=default.target' -i "${pkgdir}"/usr/lib/systemd/system/mpd.service
-}
Copied: mpd/repos/extra-x86_64/PKGBUILD (from rev 337662, mpd/trunk/PKGBUILD)
===================================================================
--- PKGBUILD (rev 0)
+++ PKGBUILD 2018-11-01 01:33:22 UTC (rev 337663)
@@ -0,0 +1,70 @@
+# Maintainer: Gaetan Bisson <bisson at archlinux.org>
+# Contributor: Angel Velasquez <angvp at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Damir Perisa <damir.perisa at bluewin.ch>
+# Contributor: Ben <ben at benmazer.net>
+
+pkgname=mpd
+pkgver=0.21
+pkgrel=1
+pkgdesc='Flexible, powerful, server-side application for playing music'
+url='https://www.musicpd.org/'
+license=('GPL')
+arch=('x86_64')
+depends=('audiofile' 'avahi' 'curl' 'faad2' 'ffmpeg' 'fluidsynth' 'icu' 'jack'
+ 'libao' 'libcdio-paranoia' 'libgme' 'libid3tag' 'libmad' 'libmikmod'
+ 'libmms' 'libmodplug' 'libmpcdec' 'libmpdclient' 'libnfs'
+ 'libsamplerate' 'libshout' 'libsoxr' 'libsystemd' 'libupnp' 'mpg123'
+ 'openal' 'smbclient' 'sqlite' 'twolame' 'wavpack' 'wildmidi' 'yajl'
+ 'zziplib')
+makedepends=('boost' 'meson' 'python-sphinx')
+validpgpkeys=('0392335A78083894A4301C43236E8A58C6DB4512')
+#source=("https://www.musicpd.org/download/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz"{,.sig}
+source=("https://www.musicpd.org/download/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.xz"{,.sig}
+ 'tmpfiles.d'
+ 'sysusers.d'
+ 'conf')
+sha256sums=('8b0ee75fb62ba69a4a127d51fb7011c60067de3f92d050184c52420d70b1528c'
+ 'SKIP'
+ '2faa85c12449a5b3ca422ff1c1fa06d057c7e262a74bfa6298c914a92d6f2e7a'
+ '0b74c6e5db08daab3091dc15a6b0c75210ba2f9e98fa074f6cfd605a461056b6'
+ 'f40f68205834ca53cea3372e930bfe6c2f9ecc9df3b1605df2fec63a658b2e03')
+
+backup=('etc/mpd.conf')
+
+prepare() {
+ cd "${srcdir}/${pkgname}-${pkgver}"
+ rm -fr build
+ install -d build
+}
+
+build() {
+ cd "${srcdir}/${pkgname}-${pkgver}/build"
+ _opts=('-Ddocumentation=true'
+ '-Dchromaprint=disabled' # appears not to be used for anything
+ '-Dsidplay=disabled' # unclear why but disabled in the past
+ '-Dlibwrap=disabled' # twentieth century's over
+ '-Dadplug=disabled' # not in an official repo
+ '-Dsndio=disabled' # interferes with detection of alsa devices
+ '-Dshine=disabled' # not in an official repo
+ )
+ arch-meson .. ${_opts[@]}
+ ninja
+}
+
+package() {
+ cd "${srcdir}/${pkgname}-${pkgver}/build"
+ DESTDIR="${pkgdir}" ninja install
+ install -Dm644 ../doc/mpdconf.example "${pkgdir}"/usr/share/doc/mpd/mpdconf.example
+ install -Dm644 ../doc/mpd.conf.5 "${pkgdir}"/usr/share/man/man5/mpd.conf.5
+ install -Dm644 ../doc/mpd.1 "${pkgdir}"/usr/share/man/man1/mpd.1
+
+ install -Dm644 ../../tmpfiles.d "${pkgdir}"/usr/lib/tmpfiles.d/mpd.conf
+ install -Dm644 ../../sysusers.d "${pkgdir}"/usr/lib/sysusers.d/mpd.conf
+ install -Dm644 ../../conf "${pkgdir}"/etc/mpd.conf
+
+ sed \
+ -e '/\[Service\]/a User=mpd' \
+ -e '/WantedBy=/c WantedBy=default.target' \
+ -i "${pkgdir}"/usr/lib/systemd/system/mpd.service
+}
Deleted: conf
===================================================================
--- conf 2018-11-01 01:32:05 UTC (rev 337662)
+++ conf 2018-11-01 01:33:22 UTC (rev 337663)
@@ -1,6 +0,0 @@
-# See: /usr/share/doc/mpd/mpdconf.example
-
-pid_file "/run/mpd/mpd.pid"
-db_file "/var/lib/mpd/mpd.db"
-state_file "/var/lib/mpd/mpdstate"
-playlist_directory "/var/lib/mpd/playlists"
Copied: mpd/repos/extra-x86_64/conf (from rev 337662, mpd/trunk/conf)
===================================================================
--- conf (rev 0)
+++ conf 2018-11-01 01:33:22 UTC (rev 337663)
@@ -0,0 +1,6 @@
+# See: /usr/share/doc/mpd/mpdconf.example
+
+pid_file "/run/mpd/mpd.pid"
+db_file "/var/lib/mpd/mpd.db"
+state_file "/var/lib/mpd/mpdstate"
+playlist_directory "/var/lib/mpd/playlists"
Deleted: sysusers.d
===================================================================
--- sysusers.d 2018-11-01 01:32:05 UTC (rev 337662)
+++ sysusers.d 2018-11-01 01:33:22 UTC (rev 337663)
@@ -1,2 +0,0 @@
-u mpd 45 - /var/lib/mpd
-m mpd audio
Copied: mpd/repos/extra-x86_64/sysusers.d (from rev 337662, mpd/trunk/sysusers.d)
===================================================================
--- sysusers.d (rev 0)
+++ sysusers.d 2018-11-01 01:33:22 UTC (rev 337663)
@@ -0,0 +1,2 @@
+u mpd 45 - /var/lib/mpd
+m mpd audio
Deleted: tmpfiles.d
===================================================================
--- tmpfiles.d 2018-11-01 01:32:05 UTC (rev 337662)
+++ tmpfiles.d 2018-11-01 01:33:22 UTC (rev 337663)
@@ -1,3 +0,0 @@
-d /run/mpd 0755 mpd mpd
-d /var/lib/mpd 0755 mpd mpd
-d /var/lib/mpd/playlists 0755 mpd mpd
Copied: mpd/repos/extra-x86_64/tmpfiles.d (from rev 337662, mpd/trunk/tmpfiles.d)
===================================================================
--- tmpfiles.d (rev 0)
+++ tmpfiles.d 2018-11-01 01:33:22 UTC (rev 337663)
@@ -0,0 +1,3 @@
+d /run/mpd 0755 mpd mpd
+d /var/lib/mpd 0755 mpd mpd
+d /var/lib/mpd/playlists 0755 mpd mpd
More information about the arch-commits
mailing list