[arch-commits] Commit in sway/repos/community-x86_64 (4 files)

[Alexander Rødseth]

    Date: Saturday, November 3, 2018 @ 11:27:30
  Author: arodseth
Revision: 401339

archrelease: copy trunk to community-x86_64

Added:
  sway/repos/community-x86_64/PKGBUILD
    (from rev 401338, sway/trunk/PKGBUILD)
  sway/repos/community-x86_64/sway.install
    (from rev 401338, sway/trunk/sway.install)
Deleted:
  sway/repos/community-x86_64/PKGBUILD
  sway/repos/community-x86_64/sway.install

--------------+
 PKGBUILD     |   96 ++++++++++++++++++++++++++-------------------------------
 sway.install |   14 ++++----
 2 files changed, 52 insertions(+), 58 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2018-11-03 11:27:24 UTC (rev 401338)
+++ PKGBUILD	2018-11-03 11:27:30 UTC (rev 401339)
@@ -1,51 +0,0 @@
-# $Id$
-
-pkgname=sway
-pkgver=0.15.2
-pkgrel=2
-pkgdesc="i3 compatible window manager for Wayland"
-arch=("x86_64")
-url="http://swaywm.org"
-license=("MIT")
-depends=(
-	"wlc" "xorg-server-xwayland" "json-c" "pango" "wayland" "gdk-pixbuf2"
-)
-optdepends=(
-	"rxvt-unicode: Default terminal emulator."
-	"dmenu: Default for launching applications."
-	"imagemagick: For taking screenshots."
-	"ffmpeg: For recording screencasts."
-	"i3status: To display system information with a bar."
-)
-makedepends=("cmake" "asciidoc")
-source=(
-	"$pkgname-$pkgver.tar.gz::https://github.com/SirCmpwn/$pkgname/archive/$pkgver.tar.gz"
-	"$pkgname-$pkgver.tar.gz::https://github.com/SirCmpwn/$pkgname/archive/$pkgver.tar.gz.sig"
-)
-install="$pkgname.install"
-sha256sums=(
-	"05526e3038d2a5490a64bd816f1f04d2a6c214ddc6182835312b273b40b737ae"
-	"SKIP"
-)
-validpgpkeys=(
-	"9DDA3B9FA5D58DD5392C78E652CB6609B22DA89A"
-)
-
-
-build() {
-	mkdir -p build
-	cd build
-        export CFLAGS="-Wno-stringop-overflow -Wno-stringop-truncation $CFLAGS"
-	cmake "$srcdir/$pkgname-$pkgver" \
-		-DCMAKE_BUILD_TYPE=Release \
-		-DCMAKE_INSTALL_SYSCONFDIR=/etc \
-		-DCMAKE_INSTALL_PREFIX=/usr \
-		-DVERSION="$pkgver"
-	make
-}
-
-package() {
-	cd build
-	DESTDIR="$pkgdir" make install
-	install -Dm644 "$srcdir/$pkgname-$pkgver/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
-}

Copied: sway/repos/community-x86_64/PKGBUILD (from rev 401338, sway/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2018-11-03 11:27:30 UTC (rev 401339)
@@ -0,0 +1,45 @@
+pkgname=sway
+pkgver=0.15.2
+pkgrel=3
+pkgdesc='Tiling Wayland compositor and replacement for the i3 window manager'
+arch=('x86_64')
+url='https://swaywm.org/'
+license=('MIT')
+depends=('gdk-pixbuf2' 'pango' 'wlc' 'xorg-server-xwayland')
+makedepends=('asciidoc' 'cmake' 'ninja')
+optdepends=(
+  'dmenu: Default for launching applications.'
+  'ffmpeg: For recording screencasts.'
+  'i3status: To display system information with a bar.'
+  'imagemagick: For taking screenshots.'
+  'rxvt-unicode: Default terminal emulator.'
+)
+validpgpkeys=('9DDA3B9FA5D58DD5392C78E652CB6609B22DA89A') # Drew DeVault
+install=$pkgname.install
+source=(
+  "$pkgname-$pkgver.tar.gz::https://github.com/swaywm/$pkgname/archive/$pkgver.tar.gz"
+  "https://github.com/swaywm/$pkgname/releases/download/$pkgver/$pkgname-$pkgver.tar.gz.sig"
+)
+sha256sums=('05526e3038d2a5490a64bd816f1f04d2a6c214ddc6182835312b273b40b737ae'
+            'SKIP')
+
+build() {
+  mkdir -p build
+  cd build
+  cmake "../$pkgname-$pkgver" \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_SYSCONFDIR=/etc \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DVERSION="$pkgver" \
+    -DCMAKE_C_FLAGS='-w' \
+    -G Ninja
+  ninja
+}
+
+package() {
+  DESTDIR="$pkgdir" ninja -C build install
+  install -Dm644 "$pkgname-$pkgver/LICENSE" \
+    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# vim: sw=2 ts=2 et:

Deleted: sway.install
===================================================================
--- sway.install	2018-11-03 11:27:24 UTC (rev 401338)
+++ sway.install	2018-11-03 11:27:30 UTC (rev 401339)
@@ -1,7 +0,0 @@
-post_install() {
-	setcap cap_sys_ptrace=eip /usr/bin/sway
-}
-
-post_upgrade() {
-	post_install $1
-}

Copied: sway/repos/community-x86_64/sway.install (from rev 401338, sway/trunk/sway.install)
===================================================================
--- sway.install	                        (rev 0)
+++ sway.install	2018-11-03 11:27:30 UTC (rev 401339)
@@ -0,0 +1,7 @@
+post_install() {
+	setcap cap_sys_ptrace=eip /usr/bin/sway
+}
+
+post_upgrade() {
+	post_install $1
+}