[arch-commits] Commit in haskell-conduit/repos (2 files)

[Felix Yan]

    Date: Wednesday, November 7, 2018 @ 15:58:02
  Author: felixonmars
Revision: 402873

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-conduit/repos/community-staging-x86_64/
  haskell-conduit/repos/community-staging-x86_64/PKGBUILD
    (from rev 402872, haskell-conduit/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-conduit/repos/community-staging-x86_64/PKGBUILD (from rev 402872, haskell-conduit/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-11-07 15:58:02 UTC (rev 402873)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=conduit
+pkgname=haskell-conduit
+pkgver=1.3.1
+pkgrel=8
+pkgdesc="Streaming data processing library."
+url="https://github.com/snoyberg/conduit"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-exceptions' 'haskell-mono-traversable' 'haskell-primitive'
+         'haskell-resourcet' 'haskell-unliftio-core' 'haskell-vector')
+makedepends=('ghc' 'haskell-hspec' 'haskell-quickcheck' 'haskell-safe' 'haskell-silently'
+             'haskell-split' 'haskell-unliftio')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('b7752a652c3fe940b9bac33be14e8e552d0eb289b69c25170aa63ba96db13cec28c53ac6f2c36a486d58948477f69cad1042026b4bd4163eb9ab96392d439ded')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}