[arch-commits] Commit in python-xapian/repos (2 files)

Felix Yan felixonmars at archlinux.org
Thu Nov 8 13:14:59 UTC 2018


    Date: Thursday, November 8, 2018 @ 13:14:58
  Author: felixonmars
Revision: 404039

archrelease: copy trunk to community-testing-x86_64

Added:
  python-xapian/repos/community-testing-x86_64/
  python-xapian/repos/community-testing-x86_64/PKGBUILD
    (from rev 404038, python-xapian/trunk/PKGBUILD)

----------+
 PKGBUILD |   62 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

Copied: python-xapian/repos/community-testing-x86_64/PKGBUILD (from rev 404038, python-xapian/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2018-11-08 13:14:58 UTC (rev 404039)
@@ -0,0 +1,62 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: David Runge <dave at sleepmap.de>
+# Contributor: DonVla <donvla/users.sourceforge/net>
+# Contributor: Hervé Cauwelier <herve/oursours/net>
+
+pkgbase=python-xapian
+pkgname=('python-xapian' 'python2-xapian')
+_realname=xapian-bindings
+pkgver=1.4.9
+epoch=1
+pkgrel=1
+pkgdesc="Python bindings for Xapian"
+arch=('x86_64')
+url="https://xapian.org/docs/bindings/python/"
+license=('GPL2')
+makedepends=('python-sphinx' 'python2-sphinx' "xapian-core=$epoch:$pkgver")
+source=("http://oligarchy.co.uk/xapian/${pkgver}/${_realname}-${pkgver}.tar.xz")
+sha512sums=('cddc6cedfd571d565619ade0a4c9bfee8d688ca3d06d77368c8d673d3c9d1296b652122836debc84a4d54724c2bf0639a009396bf587ed4b8901a6bfe508851d')
+
+prepare() {
+  cd "${_realname}-${pkgver}"
+  autoreconf -vfi
+  cd ..
+  mv -v "${_realname}-$pkgver" "${pkgname[0]}-${pkgver}"
+  cp -av "${pkgname[0]}-$pkgver" "${pkgname[1]}-${pkgver}"
+  cd "${pkgname[1]}-${pkgver}"
+  # fix shebang of examples
+  sed -i '1s/python/python2/' python/docs/examples/*.py
+  export XAPIAN_CONFIG=/usr/bin/xapian-config
+}
+
+build() {
+  cd "${pkgname[0]}-${pkgver}"
+  ./configure --prefix=/usr \
+              --with-python3
+  make
+  cd ../"${pkgname[1]}-${pkgver}"
+  PYTHON2=/usr/bin/python2
+  ./configure --prefix=/usr \
+              --with-python
+  make
+}
+
+package_python-xapian() {
+  pkgdesc="Python 3.x bindings for Xapian"
+  depends=('python' "xapian-core=$epoch:$pkgver")
+  cd "${pkgname[0]}-${pkgver}"
+  make DESTDIR="${pkgdir}" install
+  install -t "${pkgdir}/usr/share/doc/${pkgname[0]}" \
+    -vDm644 {AUTHORS,ChangeLog,HACKING,NEWS,README,TODO}
+}
+
+package_python2-xapian() {
+  pkgdesc="Python 2.x bindings for Xapian"
+  depends=('python2' "xapian-core=$epoch:$pkgver")
+  cd "${pkgname[1]}-${pkgver}"
+  make DESTDIR="$pkgdir" install
+  install -t "${pkgdir}/usr/share/doc/${pkgname[1]}" \
+    -vDm644 {AUTHORS,ChangeLog,HACKING,NEWS,README,TODO}
+}
+
+# vim:set ts=2 sw=2 et:


More information about the arch-commits mailing list