[arch-commits] Commit in python-mongoengine/repos (2 files)

[Felix Yan]

    Date: Friday, November 9, 2018 @ 19:20:08
  Author: felixonmars
Revision: 404391

archrelease: copy trunk to community-testing-any

Added:
  python-mongoengine/repos/community-testing-any/
  python-mongoengine/repos/community-testing-any/PKGBUILD
    (from rev 404390, python-mongoengine/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: python-mongoengine/repos/community-testing-any/PKGBUILD (from rev 404390, python-mongoengine/trunk/PKGBUILD)
===================================================================
--- community-testing-any/PKGBUILD	                        (rev 0)
+++ community-testing-any/PKGBUILD	2018-11-09 19:20:08 UTC (rev 404391)
@@ -0,0 +1,58 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Simon Sapin <simon dot sapin at exyr dot org>
+# Contributor: Kyle Keen <keenerd at gmail.com>
+
+pkgbase=python-mongoengine
+pkgname=(python-mongoengine python2-mongoengine)
+pkgver=0.16.0
+pkgrel=1
+pkgdesc="A Python Object-Document-Mapper for working with MongoDB"
+url="https://github.com/MongoEngine/mongoengine"
+license=('MIT')
+arch=('any')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-pymongo' 'python2-pymongo')
+checkdepends=('python-nose' 'python2-nose' 'python-coverage' 'python2-coverage'
+              'python-blinker' 'python2-blinker' 'python-pillow' 'python2-pillow' 'pifpaf' 'mongodb')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/MongoEngine/mongoengine/archive/v$pkgver.tar.gz")
+sha512sums=('99387b9e94a74fbf6422134d5c6daef2f1e753a7be1976cd4d388a47a29003fbbd6bbafa48b56ad94c8eb3a6777d06f51b3fd0ab7b992a0278574ec7c4d4c8ff')
+
+prepare() {
+  sed -i 's/coverage==/coverage>=/' mongoengine-$pkgver/setup.py
+  cp -a mongoengine-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/mongoengine-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/mongoengine-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/mongoengine-$pkgver
+  pifpaf run mongodb --port 27017 python setup.py nosetests || warning "Tests failed"
+
+  cd "$srcdir"/mongoengine-$pkgver-py2
+  pifpaf run mongodb --port 27017 python2 setup.py nosetests || warning "Tests failed"
+}
+
+package_python-mongoengine() {
+  depends=('python-pymongo' 'python-six')
+  optdepends=('python-dateutil: for DateTimeField'
+              'python-pillow: for ImageField / ImageGridFsProxy')
+
+  cd mongoengine-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-mongoengine() {
+  depends=('python2-pymongo' 'python2-six')
+  optdepends=('python2-dateutil: for DateTimeField'
+              'python2-pillow: for ImageField / ImageGridFsProxy')
+
+  cd mongoengine-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}