[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, November 9, 2018 @ 20:01:06
  Author: felixonmars
Revision: 404396

addpkg: python-mongomock 3.13.0-1

Added:
  python-mongomock/
  python-mongomock/repos/
  python-mongomock/trunk/
  python-mongomock/trunk/PKGBUILD

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Added: python-mongomock/trunk/PKGBUILD
===================================================================
--- python-mongomock/trunk/PKGBUILD	                        (rev 0)
+++ python-mongomock/trunk/PKGBUILD	2018-11-09 20:01:06 UTC (rev 404396)
@@ -0,0 +1,53 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-mongomock
+pkgname=(python-mongomock python2-mongomock)
+pkgver=3.13.0
+pkgrel=1
+pkgdesc="Fake pymongo stub for testing simple MongoDB-dependent code"
+url="https://github.com/mongomock/mongomock"
+license=('BSD')
+arch=('any')
+makedepends=('python-pbr' 'python2-pbr' 'python-sentinels' 'python2-sentinels' 'python-six'
+             'python2-six')
+checkdepends=('python-nose' 'python2-nose' 'python2-mock')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/mongomock/mongomock/archive/$pkgver.tar.gz")
+sha512sums=('bc484e6aa5e5591e70bd1c154e7b2cb7a22cedbbe5f507e81c2ce878de13279148d4b1f93b5ae8925262fc6c15928042edc6d3e958068b66c524ed4521e77350')
+
+export PBR_VERSION=$pkgver
+
+prepare() {
+  cp -a mongomock-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/mongomock-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/mongomock-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/mongomock-$pkgver
+  python setup.py nosetests
+
+  cd "$srcdir"/mongomock-$pkgver-py2
+  python2 setup.py nosetests
+}
+
+package_python-mongomock() {
+  depends=('python-sentinels' 'python-six')
+
+  cd mongomock-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-mongomock() {
+  depends=('python2-sentinels' 'python2-six')
+
+  cd mongomock-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}