[arch-commits] Commit in gtkmm/repos (staging-x86_64 staging-x86_64/PKGBUILD)
Felix Yan
felixonmars at archlinux.org
Fri Nov 9 21:04:18 UTC 2018
Date: Friday, November 9, 2018 @ 21:04:17
Author: felixonmars
Revision: 338511
archrelease: copy trunk to staging-x86_64
Added:
gtkmm/repos/staging-x86_64/
gtkmm/repos/staging-x86_64/PKGBUILD
(from rev 338510, gtkmm/trunk/PKGBUILD)
----------+
PKGBUILD | 51 +++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 51 insertions(+)
Copied: gtkmm/repos/staging-x86_64/PKGBUILD (from rev 338510, gtkmm/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2018-11-09 21:04:17 UTC (rev 338511)
@@ -0,0 +1,51 @@
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+# Contributor: Tom Newsom <Jeepster at gmx.co.uk>
+
+pkgbase=gtkmm
+pkgname=(gtkmm gtkmm-docs)
+pkgver=2.24.5+6+g85967ecc
+pkgrel=2
+pkgdesc="C++ bindings for GTK+ 2"
+url="http://www.gtkmm.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(gtk2 pangomm atkmm)
+makedepends=(git mm-common glibmm-docs cairomm-docs pangomm-docs atkmm-docs)
+_commit=85967ecc93d16892896626dfac54143b16ba9b9c # gtkmm-2-24
+source=("git+https://git.gnome.org/browse/gtkmm#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $pkgbase
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgbase
+ NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+ cd $pkgbase
+
+ # glibmm 2.46 uses C++11 features
+ CXXFLAGS+=' -std=c++11'
+
+ ./configure --prefix=/usr --enable-maintainer-mode
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+ make
+}
+
+package_gtkmm() {
+ cd $pkgbase
+ sed -i -e 's/^doc_subdirs/#doc_subdirs/' Makefile
+ make DESTDIR="$pkgdir" install
+}
+
+package_gtkmm-docs() {
+ pkgdesc+=" (documentation)"
+ depends=()
+
+ cd $pkgbase
+ make -C docs DESTDIR="$pkgdir" install
+}
More information about the arch-commits
mailing list