[arch-commits] Commit in coin-or-csdp/repos (2 files)

[Felix Yan]

    Date: Friday, November 9, 2018 @ 22:31:33
  Author: felixonmars
Revision: 404996

archrelease: copy trunk to community-staging-x86_64

Added:
  coin-or-csdp/repos/community-staging-x86_64/
  coin-or-csdp/repos/community-staging-x86_64/PKGBUILD
    (from rev 404993, coin-or-csdp/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: coin-or-csdp/repos/community-staging-x86_64/PKGBUILD (from rev 404993, coin-or-csdp/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-11-09 22:31:33 UTC (rev 404996)
@@ -0,0 +1,44 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Ido Rosen <ido at kernel.org>
+
+pkgname='coin-or-csdp'
+pkgdesc="A C library for Semidefinite Programming"
+pkgver=6.2.0
+pkgrel=2
+arch=(x86_64)
+url='https://projects.coin-or.org/Csdp/'
+license=(CPL)
+depends=(lapack)
+source=("https://www.coin-or.org/download/source/Csdp/Csdp-$pkgver.tgz")
+sha256sums=('7f202a15f33483ee205dcfbd0573fdbd74911604bb739a04f8baa35f8a055c5b')
+
+prepare() {
+  cd Csdp-$pkgver
+# don't override CFLAGS
+  sed -e '/CFLAGS/d' -i Makefile
+# don't build static lib
+  sed -e 's|-static||' -i Makefile
+}
+
+build() {
+  cd Csdp-$pkgver
+
+  CFLAGS+=" -I../include" make
+}
+
+check() {
+  cd Csdp-$pkgver
+
+  make unitTest
+}
+
+package() {
+  cd Csdp-$pkgver
+  
+  install -dm755 "$pkgdir"/usr/bin
+  install -m755 solver/csdp "$pkgdir"/usr/bin
+  install -m755 theta/{theta,graphtoprob,complement,rand_graph} "$pkgdir"/usr/bin
+
+  install -dm755 "$pkgdir"/usr/share/licenses/csdp
+  install -m644 LICENSE "$pkgdir"/usr/share/licenses/csdp
+}