[arch-commits] Commit in lib32-libasyncns/repos (2 files)

[Felix Yan]

    Date: Friday, November 9, 2018 @ 22:52:36
  Author: felixonmars
Revision: 405109

archrelease: copy trunk to multilib-staging-x86_64

Added:
  lib32-libasyncns/repos/multilib-staging-x86_64/
  lib32-libasyncns/repos/multilib-staging-x86_64/PKGBUILD
    (from rev 405108, lib32-libasyncns/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: lib32-libasyncns/repos/multilib-staging-x86_64/PKGBUILD (from rev 405108, lib32-libasyncns/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-staging-x86_64/PKGBUILD	2018-11-09 22:52:36 UTC (rev 405109)
@@ -0,0 +1,47 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Corrado Primier <bardo at aur.archlinux.org>
+# Contributor: Eric Belanger <belanger at astro.umontreal.ca>
+# Contributor: William Rea <sillywilly at gmail.com>
+# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
+
+_pkgbasename=libasyncns
+pkgname=lib32-$_pkgbasename
+pkgver=0.8+3+g68cd5af
+pkgrel=2
+pkgdesc="A C library for executing name service queries asynchronously"
+arch=(x86_64)
+url="http://0pointer.de/lennart/projects/libasyncns"
+license=(LGPL)
+depends=(lib32-glibc $_pkgbasename)
+makedepends=(gcc-multilib git lynx)
+_commit=68cd5aff1467638c086f1bedcc750e34917168e4
+source=("git://git.0pointer.de/libasyncns.git#commit=$_commit")
+md5sums=('SKIP')
+
+pkgver() {
+  cd $_pkgbasename
+  git describe | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+  cd $_pkgbasename
+
+  # Fix libdir
+  sed -i '/^libdir=/s:/lib:/lib32:' *.pc.in
+
+  NOCONFIGURE=1 ./bootstrap.sh
+}
+
+build() {
+  cd $_pkgbasename
+  export CC="gcc -m32" PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+  ./configure --prefix=/usr --libdir=/usr/lib32
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd $_pkgbasename
+  make DESTDIR="$pkgdir" install
+  rm -r "$pkgdir"/usr/{include,share}
+}