[arch-commits] Commit in tesseract-data/repos (2 files)

[Felix Yan]

    Date: Friday, November 9, 2018 @ 22:58:38
  Author: felixonmars
Revision: 405147

archrelease: copy trunk to community-staging-any

Added:
  tesseract-data/repos/community-staging-any/
  tesseract-data/repos/community-staging-any/PKGBUILD
    (from rev 405146, tesseract-data/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: tesseract-data/repos/community-staging-any/PKGBUILD (from rev 405146, tesseract-data/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2018-11-09 22:58:38 UTC (rev 405147)
@@ -0,0 +1,42 @@
+# Maintainer: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Andreas Hauser <andy-aur at splashground.de>
+
+_langs=(afr amh ara asm aze aze_cyrl bel ben bod bos bul cat ceb ces
+chi_sim chi_tra chr cym dan dan_frak deu deu_frak dzo ell eng enm epo
+equ est eus fas fin fra frk frm gle glg grc guj hat heb hin hrv hun
+iku ind isl ita ita_old jav jpn kan kat kat_old kaz khm kir kor kur
+lao lat lav lit mal mar mkd mlt msa mya nep nld nor ori pan pol
+por pus ron rus san sin slk slk_frak slv spa spa_old sqi srp srp_latn
+swa swe syr tam tel tgk tgl tha tir tur uig ukr urd uzb uzb_cyrl vie yid)
+
+pkgbase=tesseract-data
+pkgname=($(for l in ${_langs[@]}; do echo tesseract-data-${l}; done))
+epoch=1
+pkgver=3.04.00
+pkgrel=2
+pkgdesc="An OCR programm"
+arch=(any)
+url="https://github.com/tesseract-ocr/tessdata"
+license=("APACHE")
+depends=()
+source=($pkgbase-$pkgver.tar.gz::https://github.com/tesseract-ocr/tessdata/archive/$pkgver.tar.gz)
+sha256sums=('5dcb37198336b6953843b461ee535df1401b41008d550fc9e43d0edabca7adb1')
+
+build() {
+  true
+}
+
+# Declare the package functions for data
+for l in ${_langs[@]}; do
+    eval "
+package_tesseract-data-${l}(){
+    pkgdesc=\"Tesseract OCR data ($l)\"
+    depends=('tesseract')
+    groups=('tesseract-data')
+
+    mkdir -p \$pkgdir/usr/share/tessdata
+    cp \$srcdir/tessdata-$pkgver/${l}.* \$pkgdir/usr/share/tessdata/
+    find \$pkgdir/usr/share/tessdata -type f -exec chmod 0644 {} \;
+}
+    "
+done