[arch-commits] Commit in liboauth/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Evangelos Foutras]

    Date: Friday, November 9, 2018 @ 23:25:32
  Author: foutrelis
Revision: 338769

archrelease: copy trunk to staging-x86_64

Added:
  liboauth/repos/staging-x86_64/
  liboauth/repos/staging-x86_64/PKGBUILD
    (from rev 338768, liboauth/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: liboauth/repos/staging-x86_64/PKGBUILD (from rev 338768, liboauth/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2018-11-09 23:25:32 UTC (rev 338769)
@@ -0,0 +1,44 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Kaiting Chen <kaitocracy at gmail.com>
+# Contributor: Martin Häger <martin.haeger at gmail.com>
+
+pkgname=liboauth
+pkgver=1.0.3+9+g11e9461
+pkgrel=3
+pkgdesc="C library implementing OAuth Core RFC 5849"
+url="https://github.com/x42/liboauth"
+arch=(x86_64)
+license=(MIT)
+depends=(curl nss)
+makedepends=(git)
+_commit=11e9461fc433e3787198f9c01a0a565a8a1f90a9
+source=("git+$url#commit=$_commit")
+sha256sums=('SKIP')
+
+prepare() {
+  cd $pkgname
+  autoreconf -fvi
+}
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --disable-static --enable-nss
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+check() {
+  cd $pkgname
+  make check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+  install -Dm644 COPYING.MIT "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+}