[arch-commits] Commit in lib32-libnewt/repos (2 files)

Evangelos Foutras foutrelis at archlinux.org
Fri Nov 9 23:36:31 UTC 2018


    Date: Friday, November 9, 2018 @ 23:36:28
  Author: foutrelis
Revision: 405332

archrelease: copy trunk to multilib-staging-x86_64

Added:
  lib32-libnewt/repos/multilib-staging-x86_64/
  lib32-libnewt/repos/multilib-staging-x86_64/PKGBUILD
    (from rev 405331, lib32-libnewt/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: lib32-libnewt/repos/multilib-staging-x86_64/PKGBUILD (from rev 405331, lib32-libnewt/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-staging-x86_64/PKGBUILD	2018-11-09 23:36:28 UTC (rev 405332)
@@ -0,0 +1,50 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: oi_wtf <brainpower at gulli.com>
+# Contributor: Alexander Rødseth <rodseth at gmail.com>
+# Contributor: Roman Kyrylych <roman at archlinux.org>
+# Contributor: Tom Killian <tomk at runbox.com>
+# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
+
+pkgname=lib32-libnewt
+pkgver=0.52.20
+pkgrel=2
+pkgdesc="Not Erik's Windowing Toolkit - text mode windowing with slang"
+arch=('x86_64')
+url='https://fedorahosted.org/newt/'
+license=('GPL')
+depends=('lib32-glibc' 'lib32-gpm' 'lib32-popt' 'lib32-slang' 'libnewt')
+makedepends=('gcc-multilib' 'lib32-tcl')
+optdepends=('lib32-tcl: whiptcl support')
+options=('!makeflags')
+source=("https://releases.pagure.org/newt/newt-${pkgver}.tar.gz")
+sha256sums=('8d66ba6beffc3f786d4ccfee9d2b43d93484680ef8db9397a4fb70b5adbb6dbc')
+
+prepare() {
+  cd newt-${pkgver}
+
+  sed -i "s:tcl8.4:tcl8.6:" Makefile.in
+  echo '#define USE_INTERP_RESULT 1' >> config.h
+}
+
+build() {
+  cd newt-${pkgver}
+
+  export CC='gcc -m32'
+  export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
+
+  ./configure \
+    --prefix='/usr' \
+    --libdir='/usr/lib32' \
+    --with-gpm-support \
+    --without-python
+  make
+}
+
+package() {
+  cd newt-${pkgver}
+
+  make DESTDIR="${pkgdir}" install
+  rm -rf "${pkgdir}"/usr/{bin,include,share}
+}
+
+# vim: ts=2 sw=2 et:


More information about the arch-commits mailing list