[arch-commits] Commit in libzapojit/repos (staging-x86_64 staging-x86_64/PKGBUILD)
Evangelos Foutras
foutrelis at archlinux.org
Sat Nov 10 00:37:18 UTC 2018
Date: Saturday, November 10, 2018 @ 00:37:14
Author: foutrelis
Revision: 338869
archrelease: copy trunk to staging-x86_64
Added:
libzapojit/repos/staging-x86_64/
libzapojit/repos/staging-x86_64/PKGBUILD
(from rev 338868, libzapojit/trunk/PKGBUILD)
----------+
PKGBUILD | 36 ++++++++++++++++++++++++++++++++++++
1 file changed, 36 insertions(+)
Copied: libzapojit/repos/staging-x86_64/PKGBUILD (from rev 338868, libzapojit/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2018-11-10 00:37:14 UTC (rev 338869)
@@ -0,0 +1,36 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=libzapojit
+pkgver=0.0.3+11+g840627d
+pkgrel=3
+pkgdesc="GLib/GObject wrapper for the SkyDrive and Hotmail REST APIs"
+url="https://wiki.gnome.org/Projects/Zapojit"
+arch=(x86_64)
+license=(GPL)
+depends=(libsoup gnome-online-accounts)
+makedepends=(intltool gobject-introspection gnome-common git gtk-doc)
+_commit=840627d582534dafff7e05c090fb6e1a65ed2199 # master
+source=("git+https://git.gnome.org/browse/libzapojit#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+ NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+ cd $pkgname
+ ./configure --prefix=/usr --disable-static --enable-gtk-doc
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+ make
+}
+
+package() {
+ cd $pkgname
+ make DESTDIR="$pkgdir" install
+}
More information about the arch-commits
mailing list