[arch-commits] Commit in (5 files)
Alexander Rødseth
arodseth at archlinux.org
Thu Nov 15 11:26:41 UTC 2018
Date: Thursday, November 15, 2018 @ 11:26:41
Author: arodseth
Revision: 407701
Add entityx, an entity-component system
* alexthomas/entityx has 1301 stars on GitHub
* The entityx AUR pacakge is unmaintained and broken with 2 votes
* The entityx-git AUR package works great
* This package is based on the entityx-git package, but modified
Added:
entityx/
entityx/repos/
entityx/repos/community-x86_64/
entityx/trunk/
entityx/trunk/PKGBUILD
----------+
PKGBUILD | 41 +++++++++++++++++++++++++++++++++++++++++
1 file changed, 41 insertions(+)
Added: entityx/trunk/PKGBUILD
===================================================================
--- entityx/trunk/PKGBUILD (rev 0)
+++ entityx/trunk/PKGBUILD 2018-11-15 11:26:41 UTC (rev 407701)
@@ -0,0 +1,41 @@
+# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
+# Contributor: Xentec <xentec at aix0.eu>
+# Contributor: Scott Linder <scott.linder18 at gmail.com>
+
+pkgname=entityx
+pkgver=1.3.0
+pkgrel=1
+pkgdesc='Fast, type-safe C++ Entity-Component system'
+arch=('x86_64')
+url='https://github.com/alecthomas/entityx'
+license=('MIT')
+makedepends=('cmake' 'git' 'ninja')
+source=("git+$url#tag=$pkgver")
+md5sums=('SKIP')
+
+build() {
+ mkdir -p build
+ cd build
+ cmake "../$pkgname" \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_BUILD_TYPE=Release \
+ -DENTITYX_BUILD_SHARED=1 \
+ -DENTITYX_BUILD_TESTING=1 \
+ -Wno-dev \
+ -GNinja
+ ninja
+}
+
+check() {
+ ninja -C build test
+}
+
+package() {
+ DESTDIR="$pkgdir" ninja -C build install
+ install -Dm644 "$pkgname/COPYING" \
+ "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+ install -Dm644 "$pkgname/cmake/FindEntityX.cmake" \
+ "$pkgdir/usr/share/cmake-3.3/Modules/FindEntityX.cmake"
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list