[arch-commits] Commit in (4 files)

[Chih-Hsuan Yen]

    Date: Sunday, November 18, 2018 @ 07:41:50
  Author: yan12125
Revision: 408651

addpkg: python-aws-xray-sdk 2.2.0-1

Added:
  python-aws-xray-sdk/
  python-aws-xray-sdk/repos/
  python-aws-xray-sdk/trunk/
  python-aws-xray-sdk/trunk/PKGBUILD

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Added: python-aws-xray-sdk/trunk/PKGBUILD
===================================================================
--- python-aws-xray-sdk/trunk/PKGBUILD	                        (rev 0)
+++ python-aws-xray-sdk/trunk/PKGBUILD	2018-11-18 07:41:50 UTC (rev 408651)
@@ -0,0 +1,40 @@
+# Maintainer: Chih-Hsuan Yen <yan12125 at archlinux.org>
+# Contributor: Guillaume Horel <guillaume.horel at gmail.com>
+
+pkgname=python-aws-xray-sdk
+_pkgname=aws-xray-sdk-python
+pkgver=2.2.0
+pkgrel=1
+pkgdesc='AWS X-Ray SDK for Python'
+arch=(any)
+url='https://github.com/aws/aws-xray-sdk-python'
+license=(Apache)
+makedepends=(python-setuptools python-pypandoc)
+depends=(python-botocore python-future python-jsonpickle python-requests python-wrapt)
+checkdepends=(python-flask-sqlalchemy python-pynamodb python-pytest python-aiohttp
+              python-pytest-aiohttp python-testing.postgresql python-psycopg2)
+source=("$pkgname-$pkgver.tar.gz"::"https://github.com/aws/aws-xray-sdk-python/archive/$pkgver.tar.gz")
+sha256sums=('c091c85a8da2ba6e3f00b8ef3ccf92f888ec1b64ec35bcb7eeaaf714ca84576e')
+
+build() {
+  cd $_pkgname-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd $_pkgname-$pkgver
+
+  export AWS_SECRET_ACCESS_KEY=fake_key
+  export AWS_ACCESS_KEY_ID=fake_id
+
+  # aiobotocore is not compatible with botocore 1.11+, which is required by aws-xray-sdk 2.x
+  # https://github.com/aio-libs/aiobotocore/issues/629
+  # the test suite is not compatible with Django 2.x yet
+  # https://github.com/aws/aws-xray-sdk-python/issues/85
+  pytest -v --ignore tests/ext/aiobotocore --ignore tests/ext/django
+}
+
+package() {
+  cd $_pkgname-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}