[arch-commits] Commit in (5 files)

[Chih-Hsuan Yen]

    Date: Sunday, November 18, 2018 @ 14:45:52
  Author: yan12125
Revision: 408712

addpkg: buildbot 1.6.0-1

Added:
  buildbot/
  buildbot/repos/
  buildbot/trunk/
  buildbot/trunk/PKGBUILD
Deleted:
  buildbot/

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Added: buildbot/trunk/PKGBUILD
===================================================================
--- buildbot/trunk/PKGBUILD	                        (rev 0)
+++ buildbot/trunk/PKGBUILD	2018-11-18 14:45:52 UTC (rev 408712)
@@ -0,0 +1,53 @@
+# Maintainer: Chih-Hsuan Yen <yan12125 at gmail.com>
+# Contributor: xRemaLx <anton.komolov at gmail.com>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: William Rea <sillywilly at gmail.com>
+
+pkgname=buildbot
+pkgdesc='The Continuous Integration Framework'
+pkgver=1.6.0
+pkgrel=1
+arch=(any)
+url='https://buildbot.net'
+license=(GPL2)
+depends=(python-twisted python-jinja python-zope-interface python-future
+         python-sqlalchemy-migrate python-dateutil python-txaio
+         python-autobahn python-pyjwt python-yaml)
+makedepends=(git)
+checkdepends=(python-boto3 python-lz4 python-treq python-txrequests
+              python-mock python-moto python-buildbot-pkg buildbot-worker
+              python-pip openssh)
+optdepends=(
+  'python-boto3: for AWS EC2 latent worker'
+  'python-lz4: to compress logs using lz4'
+  'python-treq: for using HTTP requests as steps'
+  'python-txrequests: for using HTTP requests as steps'
+)
+source=(https://github.com/buildbot/buildbot/releases/download/v$pkgver/buildbot-v$pkgver.gitarchive.tar.gz{,.sig})
+sha256sums=('1d6dbab6cc3fa77cf709589d93bd86de030dc9bf244eebca1f16c388ed27d24a'
+            'SKIP')
+validpgpkeys=(
+  '390EB159056ED56F66AB1092AECD456B4D2531FC'  # Pierre Tardy <tardyp at gmail.com>
+)
+
+build() {
+  cd buildbot-$pkgver/master
+  python setup.py build
+}
+
+check() {
+  cd buildbot-$pkgver/master
+
+  # https://github.com/spulec/moto/issues/1924
+  export AWS_SECRET_ACCESS_KEY=foobar_secret
+  export AWS_ACCESS_KEY_ID=foobar_key
+
+  pip install --root="$srcdir"/tmp_install .
+
+  PYTHONPATH="$srcdir"/tmp_install/usr/lib/python3.7/site-packages TZ=UTC trial3 --rterrors buildbot
+}
+
+package() {
+  cd buildbot-$pkgver/master
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}