[arch-commits] Commit in digikam/repos (3 files)

Antonio Rojas arojas at archlinux.org
Sun Nov 18 16:55:41 UTC 2018


    Date: Sunday, November 18, 2018 @ 16:55:40
  Author: arojas
Revision: 340101

archrelease: copy trunk to staging-x86_64

Added:
  digikam/repos/staging-x86_64/
  digikam/repos/staging-x86_64/PKGBUILD
    (from rev 340100, digikam/trunk/PKGBUILD)
  digikam/repos/staging-x86_64/digikam-opencv4.patch
    (from rev 340100, digikam/trunk/digikam-opencv4.patch)

-----------------------+
 PKGBUILD              |   77 ++++++++++++++++++++++++++++++++++++++++++++++++
 digikam-opencv4.patch |   56 ++++++++++++++++++++++++++++++++++
 2 files changed, 133 insertions(+)

Copied: digikam/repos/staging-x86_64/PKGBUILD (from rev 340100, digikam/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2018-11-18 16:55:40 UTC (rev 340101)
@@ -0,0 +1,77 @@
+# Maintainer: Ronald van Haren <ronald at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Tobias Powalowski <tpowa at archlinux.org>
+
+pkgbase=digikam
+pkgname=(digikam kipi-plugins)
+_pkgver=5.9.0
+pkgver=${_pkgver//-/_} # for beta versions
+pkgrel=3
+pkgdesc="An advanced digital photo management application"
+arch=(x86_64)
+license=(GPL)
+url="http://www.digikam.org/"
+makedepends=(extra-cmake-modules libkipi libksane liblqr opencv doxygen lensfun eigen boost kdoctools marble-common
+             kfilemetadata akonadi-contacts qtav threadweaver kcalcore knotifyconfig libmediawiki libkvkontakte glu)
+source=("http://download.kde.org/stable/${pkgname}/${pkgname}-${_pkgver}.tar.xz"
+        kdebug-395875.patch::"https://cgit.kde.org/digikam.git/patch/core?id=486e34a0"
+        digikam-opencv4.patch)
+sha256sums=('660d32eedcfd6fe1a75170a651fab068ae62f7f092ae710771a2f32a1c550d1b'
+            '3910f0f36ef933649691fe6da47f205d86d79afa9b4f239f86dd540648b55731'
+            '621faf691d081239d792616ea40bac7a1cc07c3adf1bc74b4adc9107eacb4232')
+
+prepare() {
+  mkdir -p build
+
+  cd $pkgbase-$pkgver
+  patch -p1 -i ../kdebug-395875.patch   # Fix window state saving on close
+  patch -p1 -i ../digikam-opencv4.patch # fix build with openCV 4
+}
+
+build() {
+  cd build
+
+  cmake ../$pkgname-${_pkgver} \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF \
+    -DENABLE_KFILEMETADATASUPPORT=ON \
+    -DENABLE_MEDIAPLAYER=ON \
+    -DENABLE_AKONADICONTACTSUPPORT=ON \
+    -DENABLE_MYSQLSUPPORT=ON \
+    -DENABLE_OPENCV3=ON \
+    -DENABLE_APPSTYLES=ON
+  make
+}
+
+package_digikam() {
+  depends=(liblqr libkipi lensfun opencv akonadi-contacts knotifyconfig libksane kfilemetadata qtav marble-common threadweaver kcalcore)
+  optdepends=('kipi-plugins: export to various online services'
+              'hugin: panorama tool' 'qt5-imageformats: support for additional image formats (WEBP, TIFF)')
+
+  cd build/core
+  make DESTDIR="$pkgdir" install
+  cd $srcdir/build/doc
+  make DESTDIR="$pkgdir" install
+  cd $srcdir/build/po
+  make DESTDIR="$pkgdir" install
+
+# Provided by kipi-plugins
+  rm "$pkgdir"/usr/share/locale/*/LC_MESSAGES/kipiplugin*.mo
+}
+
+package_kipi-plugins() {
+  pkgdesc="A collection of plugins extending the KDE graphics and image applications as digiKam"
+  depends=(kio libkipi)
+  optdepends=('libmediawiki: MediaWiki Export plugin'
+              'libkvkontakte: VKontakte.ru Exporter plugin')
+
+  cd build/extra
+  make DESTDIR="$pkgdir" install
+  cd $srcdir/build/po
+  make DESTDIR="$pkgdir" install
+
+# Provided by digikam
+  rm "$pkgdir"/usr/share/locale/*/LC_MESSAGES/digikam.mo
+}

Copied: digikam/repos/staging-x86_64/digikam-opencv4.patch (from rev 340100, digikam/trunk/digikam-opencv4.patch)
===================================================================
--- staging-x86_64/digikam-opencv4.patch	                        (rev 0)
+++ staging-x86_64/digikam-opencv4.patch	2018-11-18 16:55:40 UTC (rev 340101)
@@ -0,0 +1,56 @@
+diff --git a/core/app/utils/digikam_opencv.h.cmake.in b/core/app/utils/digikam_opencv.h.cmake.in
+index 9195aad6e7..b3d6de1f86 100644
+--- a/core/app/utils/libopencv.h.cmake.in
++++ b/core/app/utils/libopencv.h.cmake.in
+@@ -54,24 +54,36 @@
+ #   include <opencv2/legacy/compat.hpp>
+ #   include <opencv/cvaux.h>
+ #   include <opencv2/imgproc/imgproc.hpp>
+-#else
++#elif OPENCV_TEST_VERSION(4,0,0)
+ #   include <opencv/cv.h>
+ #   include <opencv/cvaux.h>
+ #   include <opencv/cxcore.h>
+ #   include <opencv2/imgproc.hpp>
++#else
++#   include <opencv2/imgproc.hpp>
++#   include <opencv2/core/core_c.h>
++#   include <opencv2/core/types_c.h>
++#   include <opencv2/imgproc/types_c.h>
+ #endif
+ 
+ #if OPENCV_TEST_VERSION(3,0,0)
+ #   include <opencv2/core/core.hpp>
+ #   include <opencv2/core/internal.hpp>
+ #   include <opencv2/contrib/contrib.hpp>
+-#else
++#elif OPENCV_TEST_VERSION(4,0,0)
+ #   include <opencv2/objdetect.hpp>
+ #   include <opencv2/core.hpp>
+ #   include <opencv2/core/utility.hpp>
+ #   include <opencv2/core/persistence.hpp>
+ #   include <opencv2/imgcodecs.hpp>
+ #   include <opencv2/imgcodecs/imgcodecs_c.h>
++#else
++#   include <opencv2/objdetect.hpp>
++#   include <opencv2/core.hpp>
++#   include <opencv2/core/utility.hpp>
++#   include <opencv2/core/persistence.hpp>
++#   include <opencv2/imgcodecs.hpp>
++#   include <opencv2/imgcodecs/legacy/constants_c.h>
+ #endif
+ 
+ // for old-style code
+diff --git a/core/libs/facesengine/detection/opencvfacedetector.cpp b/core/libs/facesengine/detection/opencvfacedetector.cpp
+index 2a28276d09..639540a964 100644
+--- a/core/libs/facesengine/detection/opencvfacedetector.cpp
++++ b/core/libs/facesengine/detection/opencvfacedetector.cpp
+@@ -358,7 +358,7 @@ void OpenCVFaceDetector::updateParameters(const cv::Size& /*scaledSize*/, const
+      * unless in we want very high sensitivity at low speed
+      */
+     if (d->sensitivityVsSpecificity > 0.1 || d->speedVsAccuracy < 0.9)
+-        d->primaryParams.flags = CV_HAAR_DO_CANNY_PRUNING;
++        d->primaryParams.flags = cv::CASCADE_DO_CANNY_PRUNING;
+     else
+         d->primaryParams.flags = 0;
+ 



More information about the arch-commits mailing list