[arch-commits] Commit in dragonfly-reverb/repos (2 files)

[David Runge]

    Date: Monday, November 19, 2018 @ 16:52:17
  Author: dvzrv
Revision: 408882

archrelease: copy trunk to community-x86_64

Added:
  dragonfly-reverb/repos/community-x86_64/
  dragonfly-reverb/repos/community-x86_64/PKGBUILD
    (from rev 408881, dragonfly-reverb/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: dragonfly-reverb/repos/community-x86_64/PKGBUILD (from rev 408881, dragonfly-reverb/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2018-11-19 16:52:17 UTC (rev 408882)
@@ -0,0 +1,44 @@
+# Maintainer: David Runge <dave at sleepmap.de>
+pkgname=dragonfly-reverb
+_name=DragonflyReverb
+pkgver=1.0.0
+pkgrel=1
+pkgdesc="A free hall-style reverb based on freeverb3 algorithms"
+arch=('x86_64')
+url="https://github.com/michaelwillis/dragonfly-reverb"
+license=('GPL3')
+groups=('pro-audio' 'lv2-plugins' 'vst-plugins')
+depends=('jack' 'libglvnd')
+makedepends=('gendesk' 'liblo' 'lv2')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/michaelwillis/${pkgname}/releases/download/${pkgver}/${_name}-source-v${pkgver}.tar.gz")
+sha512sums=('5cff7a0ce02bc1c57a06bf6ab45dc53e52018942c1d518693d77ad1b9f1f98e28cf9efccb98f8b43531af9577aa24cc4f519437290f5a641365ac5a0f2ef9c29')
+
+prepare() {
+  mv -v "DragonflyReverb-source-v${pkgver}" "$pkgname-$pkgver"
+  cd "$pkgname-$pkgver"
+  # XDG desktop file
+  gendesk -n \
+          --pkgname ${pkgname} \
+          --pkgdesc "${pkgdesc}" \
+          --name DragonflyReverb \
+          --exec DragonflyReverb \
+          --categories "AudioVideo;Audio"
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  make
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  install -vDm 755 "bin/${_name}" -t "${pkgdir}/usr/bin"
+  install -vDm 644 "${pkgname}.desktop" \
+    -t "${pkgdir}/usr/share/applications/"
+  install -vDm 755 "bin/${_name}-vst.so" -t "${pkgdir}/usr/lib/vst"
+  install -vDm 755 "bin/${_name}.lv2/"*.so \
+    -t "${pkgdir}/usr/lib/lv2/${_name}.lv2/"
+  install -vDm 644 "bin/${_name}.lv2/"*.ttl \
+    -t "${pkgdir}/usr/lib/lv2/${_name}.lv2/"
+  install -vDm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+}