[arch-commits] Commit in (4 files)

[Kyle Keen]

    Date: Monday, November 19, 2018 @ 18:30:12
  Author: kkeen
Revision: 408953

pkginit: old prompt_toolkit for ipython

Added:
  python2-prompt_toolkit1/
  python2-prompt_toolkit1/repos/
  python2-prompt_toolkit1/trunk/
  python2-prompt_toolkit1/trunk/PKGBUILD

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Added: python2-prompt_toolkit1/trunk/PKGBUILD
===================================================================
--- python2-prompt_toolkit1/trunk/PKGBUILD	                        (rev 0)
+++ python2-prompt_toolkit1/trunk/PKGBUILD	2018-11-19 18:30:12 UTC (rev 408953)
@@ -0,0 +1,44 @@
+# Maintainer: Kyle Keen <keenerd at gmail.com>
+# Contributor: Andy Weidenbaum <archbaum at gmail.com>
+
+pkgname=python2-prompt_toolkit1
+_name=prompt_toolkit
+pkgver=1.0.15
+pkgrel=1
+pkgdesc="Library for building powerful interactive command lines in Python"
+arch=('any')
+depends=('python2-pygments'
+         'python2-six'
+         'python2-wcwidth')
+makedepends=('python2-setuptools' 'python2-pygments' 'python2-six'
+             'python2-wcwidth')
+url="https://github.com/jonathanslenders/python-prompt-toolkit"
+license=('BSD')
+options=(!emptydirs)
+source=("https://files.pythonhosted.org/packages/source/p/$_name/$_name-$pkgver.tar.gz")
+md5sums=('8fe70295006dbc8afedd43e5eba99032')
+sha256sums=('858588f1983ca497f1cf4ffde01d978a3ea02b01c8a26a8bbc5cd2e66d816917')
+
+prepare() {
+  cd "$srcdir"
+  cp -r $_name-$pkgver python2-$_name-$pkgver
+  # rearrange a bunch of stuff to avoid version conflicts
+  cd "$srcdir/python2-$_name-$pkgver"
+  mv -f prompt_toolkit prompt_toolkit1
+  find ./ -type f -exec sed -i -e 's/prompt_toolkit/prompt_toolkit1/g' {} \;
+}
+
+build() {
+  cd "$srcdir/python2-$_name-$pkgver"
+  python2 setup.py build
+}
+
+package() {
+  depends=('python2-pygments'
+           'python2-six'
+           'python2-wcwidth')
+  cd "$srcdir/python2-$_name-$pkgver"
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+