[arch-commits] Commit in (4 files)

[Sven-Hendrik Haase]

    Date: Sunday, November 25, 2018 @ 11:38:40
  Author: svenstaro
Revision: 409689

Add openscenegraph34 for openmw

Added:
  openscenegraph34/
  openscenegraph34/repos/
  openscenegraph34/trunk/
  openscenegraph34/trunk/PKGBUILD

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Added: openscenegraph34/trunk/PKGBUILD
===================================================================
--- openscenegraph34/trunk/PKGBUILD	                        (rev 0)
+++ openscenegraph34/trunk/PKGBUILD	2018-11-25 11:38:40 UTC (rev 409689)
@@ -0,0 +1,42 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
+# Contributor: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Hans Janssen <janserv at gmail.com>
+# Contributor: my64 <packages at obordes.com>
+# Contributor: Colin Pitrat <colin.pitrat at gmail.com>
+
+pkgname=openscenegraph34
+pkgver=3.4.1
+pkgrel=1
+pkgdesc='Open Source, high performance real-time graphics toolkit (version 3.4)'
+url='http://www.openscenegraph.org'
+arch=('x86_64')
+license=('custom:OSGPL')
+depends=('giflib' 'jasper' 'librsvg' 'xine-lib' 'curl' 'pth')
+makedepends=('cmake' 'libvncserver' 'qt5-base' 'ffmpeg' 'mesa')
+optdepends=('libvncserver' 'gdal' 'openexr' 'poppler-glib' 'qt5-base' 'ffmpeg')
+conflicts=('openthreads' 'openscenegraph')
+provides=('openthreads' 'openscenegraph')
+source=(https://github.com/openscenegraph/OpenSceneGraph/archive/OpenSceneGraph-${pkgver}.tar.gz)
+sha256sums=('930eb46f05781a76883ec16c5f49cfb29a059421db131005d75bec4d78401fd5')
+sha512sums=('4a65625e208d24256b5564bbe9d6f557758b51fae0acf85d1f71968a237fec299088536830fc862d25e02039de9ea13176b298a68aaa644eac958acbe1f4e143')
+
+build() {
+  mkdir -p OpenSceneGraph-OpenSceneGraph-${pkgver}/build
+  cd OpenSceneGraph-OpenSceneGraph-${pkgver}/build
+  cmake \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    ..
+  make
+}
+
+package() {
+  cd OpenSceneGraph-OpenSceneGraph-${pkgver}
+  make -C build DESTDIR="${pkgdir}" install
+  install -Dm 644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  mv "${pkgdir}/usr/lib64" "${pkgdir}/usr/lib"
+}
+
+# vim: ts=2 sw=2 et: