[arch-commits] Commit in pyqt5/repos (testing-x86_64 testing-x86_64/PKGBUILD)
Antonio Rojas
arojas at archlinux.org
Wed Oct 3 11:31:46 UTC 2018
Date: Wednesday, October 3, 2018 @ 11:31:46
Author: arojas
Revision: 335671
archrelease: copy trunk to testing-x86_64
Added:
pyqt5/repos/testing-x86_64/
pyqt5/repos/testing-x86_64/PKGBUILD
(from rev 335670, pyqt5/trunk/PKGBUILD)
----------+
PKGBUILD | 107 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 107 insertions(+)
Copied: pyqt5/repos/testing-x86_64/PKGBUILD (from rev 335670, pyqt5/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2018-10-03 11:31:46 UTC (rev 335671)
@@ -0,0 +1,107 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Yichao Yu <yyc1992 at gmail.com>
+# Contributor: Douglas Soares de Andrade <douglas at archlinux.org>
+# Contributor: riai <riai at bigfoot.com> Ben <ben at benmazer.net>
+
+pkgbase=pyqt5
+pkgname=('pyqt5-common' 'python-pyqt5' 'python2-pyqt5')
+pkgver=5.11.3
+pkgrel=1
+arch=('x86_64')
+url="http://riverbankcomputing.co.uk/software/pyqt/intro"
+license=('GPL')
+makedepends=('python-sip-pyqt5' 'python2-sip-pyqt5' 'sip' 'python-opengl' 'python2-opengl' 'python2-enum34'
+ 'python2-dbus' 'python-dbus' 'qt5-connectivity' 'qt5-multimedia' 'qt5-tools' 'qt5-serialport' 'qt5-svg'
+ 'qt5-webengine' 'qt5-webkit' 'qt5-websockets' 'qt5-x11extras' 'qt5-networkauth')
+source=("http://sourceforge.net/projects/pyqt/files/PyQt5/PyQt-$pkgver/PyQt5_gpl-$pkgver.tar.gz")
+sha512sums=('6f4abb1866ce357263c208121607072e127c8853e9c6bf039b034fefdda4c40e38f917c3b313375f0d692d764ecf26ff3a6b12cda2a2eeb5237db8b5e9443548')
+
+prepare() {
+ cp -a PyQt5_gpl-$pkgver{,-py2}
+}
+
+build() {
+ cd "$srcdir"/PyQt5_gpl-$pkgver
+ python configure.py \
+ --confirm-license \
+ --no-sip-files \
+ --qsci-api
+ make
+
+ cd "$srcdir"/PyQt5_gpl-$pkgver-py2
+ python2 configure.py \
+ --confirm-license \
+ --no-sip-files \
+ --qsci-api
+ make
+}
+
+package_pyqt5-common(){
+ pkgdesc="Common PyQt files shared between python-pyqt5 and python2-pyqt5"
+ depends=('qt5-base')
+
+ cd PyQt5_gpl-$pkgver
+ install -Dm644 PyQt5.api "$pkgdir"/usr/share/qt/qsci/api/python/PyQt5.api
+
+ install -d "$pkgdir"/usr/share/sip/PyQt5
+ cp -a sip/* "$pkgdir"/usr/share/sip/PyQt5
+}
+
+package_python-pyqt5(){
+ pkgdesc="A set of Python 3.x bindings for the Qt5 toolkit"
+ depends=('python-sip-pyqt5' 'pyqt5-common')
+ optdepends=('python-opengl: enable OpenGL 3D graphics in PyQt applications'
+ 'python-dbus: for python-dbus mainloop support'
+ 'qt5-multimedia: QtMultimedia, QtMultimediaWidgets'
+ 'qt5-tools: QtHelp, QtDesigner'
+ 'qt5-svg: QtSvg'
+ 'qt5-webkit: QtWebKit, QtWebKitWidgets'
+ 'qt5-xmlpatterns: QtXmlPatterns'
+ 'qt5-declarative: QtQml, qmlplugin'
+ 'qt5-serialport: QtSerialPort'
+ 'qt5-websockets: QtWebSockets'
+ 'qt5-connectivity: QtNfc, QtBluetooth'
+ 'qt5-webengine: QtWebEngine, QtWebEngineCore, QtWebEngineWidgets'
+ 'qt5-x11extras: QtX11Extras'
+ 'qt5-networkauth: QtNetworkAuth')
+
+ cd PyQt5_gpl-$pkgver
+ # INSTALL_ROOT is needed for the QtDesigner module, the other Makefiles use DESTDIR
+ make DESTDIR="$pkgdir" INSTALL_ROOT="$pkgdir" install -j1
+
+ # Provided by pyqt-common
+ rm "$pkgdir"/usr/share/qt/qsci/api/python/PyQt5.api
+}
+
+package_python2-pyqt5(){
+ pkgdesc="A set of Python 2.x bindings for the Qt5 toolkit"
+ depends=('python2-sip-pyqt5' 'pyqt5-common' 'python2-enum34')
+ optdepends=('python2-opengl: enable OpenGL 3D graphics in PyQt applications'
+ 'python-dbus: for python-dbus mainloop support'
+ 'qt5-multimedia: QtMultimedia, QtMultimediaWidgets'
+ 'qt5-tools: QtHelp, QtDesigner'
+ 'qt5-svg: QtSvg'
+ 'qt5-webkit: QtWebKit, QtWebKitWidgets'
+ 'qt5-xmlpatterns: QtXmlPatterns'
+ 'qt5-declarative: QtQml, qmlplugin'
+ 'qt5-serialport: QtSerialPort'
+ 'qt5-websockets: QtWebSockets'
+ 'qt5-connectivity: QtNfc, QtBluetooth'
+ 'qt5-webengine: QtWebEngine, QtWebEngineCore, QtWebEngineWidgets'
+ 'qt5-x11extras: QtX11Extras'
+ 'qt5-networkauth: QtNetworkAuth')
+
+ cd PyQt5_gpl-$pkgver-py2
+ # INSTALL_ROOT is needed for the QtDesigner module, the other Makefiles use DESTDIR
+ make DESTDIR="$pkgdir" INSTALL_ROOT="$pkgdir" install -j1
+
+ # Fix conflicts with python-pyqt5
+ mv "$pkgdir"/usr/bin/{,python2-}pyuic5
+ mv "$pkgdir"/usr/bin/{,python2-}pylupdate5
+ mv "$pkgdir"/usr/bin/{,python2-}pyrcc5
+
+ rm "$pkgdir"/usr/lib/qt/plugins/designer/libpyqt5.so
+ rm "$pkgdir"/usr/lib/qt/plugins/PyQt5/libpyqt5qmlplugin.so
+ rm "$pkgdir"/usr/share/qt/qsci/api/python/PyQt5.api
+}
More information about the arch-commits
mailing list