[arch-commits] Commit in collectd/repos (3 files)

[Felix Yan]

    Date: Tuesday, October 9, 2018 @ 18:17:58
  Author: felixonmars
Revision: 391721

archrelease: copy trunk to community-testing-x86_64

Added:
  collectd/repos/community-testing-x86_64/
  collectd/repos/community-testing-x86_64/PKGBUILD
    (from rev 391720, collectd/trunk/PKGBUILD)
  collectd/repos/community-testing-x86_64/service
    (from rev 391720, collectd/trunk/service)

----------+
 PKGBUILD |   74 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 service  |   13 ++++++++++
 2 files changed, 87 insertions(+)

Copied: collectd/repos/community-testing-x86_64/PKGBUILD (from rev 391720, collectd/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2018-10-09 18:17:58 UTC (rev 391721)
@@ -0,0 +1,74 @@
+# Maintainer: Gaetan Bisson <bisson at archlinux.org>
+# Contributor: Gerhard Brauer <gerhard.brauer at web.de>
+
+pkgname=collectd
+pkgver=5.8.0
+pkgrel=11
+pkgdesc='Daemon which collects system performance statistics periodically'
+url='https://collectd.org/'
+arch=('x86_64')
+license=('GPL')
+
+optdepends=('curl: apache, ascent, curl, nginx, and write_http plugins'
+            'libdbi: dbi plugin'
+            'libesmtp: notify_email plugin'
+            'libgcrypt: encryption and authentication for network plugin'
+            'libmemcached: memcachec plugin'
+            'libmariadbclient: mysql plugin'
+            'libsystemd: UdevNameAttr option'
+            'iproute2: netlink plugin'
+            'net-snmp: snmp plugin'
+            'libnotify: notify_desktop plugin'
+            'openipmi: ipmi plugin'
+            'liboping: ping plugin'
+            'libpcap: dns plugin'
+            'perl: perl plugin'
+            'postgresql-libs: postgresql plugin'
+            'python: python plugin'
+            'rrdtool: rrdtool and rrdcached plugins'
+            'lm_sensors: lm_sensors and sensors plugins'
+            'libvirt: libvirt plugin'
+            'libxml2: ascent and libvirt plugins'
+            'yajl: curl_json plugin'
+            'libatasmart: smart plugin'
+            'lvm2: lvm plugin'
+            'protobuf-c: write_riemann plugin'
+            'mosquitto: MQTT plugin'
+            'libmicrohttpd: prometheus plugin'
+            'librabbitmq-c: amqp plugin')
+
+makedepends=(${optdepends[@]%:*})
+depends=('libltdl' 'iptables' 'libnsl')
+
+source=("${url}files/${pkgname}-${pkgver}.tar.bz2"
+        'service')
+sha512sums=('1b3d0cc44e2ca54e13eebf292074f1efa8b33d6800d04405e0eaaa2dd1cb2416c6eae580729fb5aead23a5039f41ffe8a9989a907a8c18be8f867f1099fc0008'
+            '736ffa8a8b4a738d75acd2fc272ef88e23cc2d0c64dd91746d48707a54eebe805998c0ea10c89db96bbe1e11d9b27212c2997854805c8d022d9ae2d89ae4fa50')
+
+backup=('etc/collectd.conf')
+
+prepare() {
+	cd "${srcdir}/${pkgname}-${pkgver}"
+	sed 's/ -Werror//g' -i configure
+}
+
+build() {
+	cd "${srcdir}/${pkgname}-${pkgver}"
+	export MAKEFLAGS='-j1'
+	./configure \
+		--prefix=/usr \
+		--sysconfdir=/etc \
+		--localstatedir=/var \
+		--sbindir=/usr/bin \
+		--with-python=/usr/bin/python \
+		--with-perl-bindings='INSTALLDIRS=vendor'
+	make all
+}
+
+package() {
+	cd "${srcdir}/${pkgname}-${pkgver}"
+	make DESTDIR="${pkgdir}" install
+	rmdir "${pkgdir}/var/run" # FS#30201
+	install -Dm644 ../service "${pkgdir}"/usr/lib/systemd/system/collectd.service
+	install -Dm644 contrib/collectd2html.pl "${pkgdir}"/usr/share/collectd/collectd2html.pl
+}

Copied: collectd/repos/community-testing-x86_64/service (from rev 391720, collectd/trunk/service)
===================================================================
--- community-testing-x86_64/service	                        (rev 0)
+++ community-testing-x86_64/service	2018-10-09 18:17:58 UTC (rev 391721)
@@ -0,0 +1,13 @@
+[Unit]
+Description=System statistics collection daemon
+After=local-fs.target network.target
+
+[Service]
+Type=forking
+PIDFile=/run/collectdmon.pid
+ExecStart=/usr/bin/collectdmon
+ExecReload=/bin/kill -HUP $MAINPID
+Restart=always
+
+[Install]
+WantedBy=multi-user.target