[arch-commits] Commit in (4 files)

Felix Yan felixonmars at archlinux.org
Wed Oct 17 17:39:20 UTC 2018


    Date: Wednesday, October 17, 2018 @ 17:39:20
  Author: felixonmars
Revision: 395064

addpkg: haskell-githash 0.1.1.0-1

Added:
  haskell-githash/
  haskell-githash/repos/
  haskell-githash/trunk/
  haskell-githash/trunk/PKGBUILD

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Added: haskell-githash/trunk/PKGBUILD
===================================================================
--- haskell-githash/trunk/PKGBUILD	                        (rev 0)
+++ haskell-githash/trunk/PKGBUILD	2018-10-17 17:39:20 UTC (rev 395064)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=githash
+pkgname=haskell-githash
+pkgver=0.1.1.0
+pkgrel=1
+pkgdesc="Some handy Template Haskell splices for including the current git hash and branch in the code of your project"
+url="https://github.com/snoyberg/githash"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'git')
+makedepends=('ghc' 'haskell-hpack' 'haskell-hspec' 'haskell-temporary' 'haskell-unliftio')
+source=("git+https://github.com/snoyberg/githash.git#tag=githash-$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+    cd $_hkgname
+    hpack
+}
+
+build() {
+    cd $_hkgname
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname
+    
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}



More information about the arch-commits mailing list