[arch-commits] Commit in ogre/repos (3 files)

[Sven-Hendrik Haase]

    Date: Wednesday, October 17, 2018 @ 22:42:05
  Author: svenstaro
Revision: 395763

archrelease: copy trunk to community-staging-x86_64

Added:
  ogre/repos/community-staging-x86_64/
  ogre/repos/community-staging-x86_64/PKGBUILD
    (from rev 395760, ogre/trunk/PKGBUILD)
  ogre/repos/community-staging-x86_64/ogre.install
    (from rev 395761, ogre/trunk/ogre.install)

--------------+
 PKGBUILD     |   69 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 ogre.install |    3 ++
 2 files changed, 72 insertions(+)

Copied: ogre/repos/community-staging-x86_64/PKGBUILD (from rev 395760, ogre/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-10-17 22:42:05 UTC (rev 395763)
@@ -0,0 +1,69 @@
+# Maintainer: Sven-Hendrik Haase <sh at lutzhaase.com>
+pkgbase=ogre
+pkgname=('ogre' 'ogre-docs')
+pkgver=1.11.2
+pkgrel=2
+pkgdesc='Scene-oriented, flexible 3D engine written in C++'
+arch=('x86_64')
+url='http://www.ogre3d.org'
+license=('custom:MIT')
+depends=('freeimage' 'freetype2' 'libxaw' 'libxrandr' 'openexr'
+         'nvidia-cg-toolkit' 'zziplib' 'sdl2' 'glu' 'tinyxml')
+makedepends=('cmake' 'doxygen' 'graphviz' 'ttf-dejavu' 'mesa' 'python' 'swig' 'systemd' 'java-environment')
+install=ogre.install
+source=("https://github.com/OGRECave/ogre/archive/v${pkgver}.tar.gz")
+sha512sums=('81f40b4bd25ac91db3dca205f1b9c12e9120706626d81dff70b2b8836d8dbffe49e7d102528630d4c6b730834c50745de9c03fab354826f813d3479c2f7097fc')
+
+build() {
+  cd ogre-${pkgver}
+
+  [[ -d build ]] && rm -rf build
+  mkdir build && cd build
+
+  export JAVA_HOME=/usr/lib/jvm/default
+
+  cmake .. \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DOGRE_BUILD_DEPENDENCIES=FALSE \
+    -DCMAKE_BUILD_TYPE=RelWithDebInfo \
+    -DOGRE_BUILD_PLUGIN_FREEIMAGE=TRUE \
+    -DOGRE_BUILD_PLUGIN_EXRCODEC=TRUE
+
+  make
+  make OgreDoc
+}
+
+package_ogre() {
+  optdepends=('cppunit: unit testing'
+              'python: python bindings'
+              'java-environment: jni bindings'
+              'ogre-docs: documentation')
+
+  cd ogre-${pkgver}/build
+
+  make DESTDIR=${pkgdir} install
+
+  mv ${pkgdir}/usr/bin/SampleBrowser ${pkgdir}/usr/bin/OgreSampleBrowser
+  install -Dm644 ../LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
+
+  # move docs out of this package
+  mv ${pkgdir}/usr/share/OGRE/docs ${srcdir}/docs
+}
+
+package_ogre-docs() {
+  pkgdesc="Documentation for ogre"
+  depends=()
+
+  cd ogre-${pkgver}/build
+
+  # move docs into this package
+  install -dm755 ${pkgdir}/usr/share/doc
+  mv ${srcdir}/docs ${pkgdir}/usr/share/doc/OGRE/
+
+  # symlink for docs
+  install -dm755 ${pkgdir}/usr/share/OGRE/
+  cd ${pkgdir}/usr/share
+  ln -s /usr/share/doc/OGRE/ OGRE/docs
+}
+
+# vim:set ts=2 sw=2 et:

Copied: ogre/repos/community-staging-x86_64/ogre.install (from rev 395761, ogre/trunk/ogre.install)
===================================================================
--- community-staging-x86_64/ogre.install	                        (rev 0)
+++ community-staging-x86_64/ogre.install	2018-10-17 22:42:05 UTC (rev 395763)
@@ -0,0 +1,3 @@
+post_install() {
+    echo "To view the OGRE samples just run OgreSampleBrowser"
+}