[arch-commits] Commit in hledger/repos (2 files)

[Felix Yan]

    Date: Friday, October 19, 2018 @ 13:22:37
  Author: felixonmars
Revision: 397551

archrelease: copy trunk to community-staging-x86_64

Added:
  hledger/repos/community-staging-x86_64/
  hledger/repos/community-staging-x86_64/PKGBUILD
    (from rev 397550, hledger/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: hledger/repos/community-staging-x86_64/PKGBUILD (from rev 397550, hledger/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-10-19 13:22:37 UTC (rev 397551)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=hledger
+pkgver=1.11.1
+pkgrel=7
+pkgdesc="Command-line interface for the hledger accounting tool"
+url="http://hledger.org"
+license=("GPL")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ansi-terminal' 'haskell-base-compat-batteries' 'haskell-cmdargs'
+         'haskell-data-default' 'haskell-decimal' 'haskell-diff' 'haskell-easytest'
+         'haskell-file-embed' 'haskell-hashable' 'haskell-here' 'haskell-hledger-lib'
+         'haskell-lucid' 'haskell-megaparsec' 'haskell-old-time' 'haskell-pretty-show'
+         'haskell-regex-tdfa' 'haskell-safe' 'haskell-shakespeare' 'haskell-split'
+         'haskell-statistics' 'haskell-tabular' 'haskell-temporary' 'haskell-unordered-containers'
+         'haskell-utf8-string' 'haskell-utility-ht' 'haskell-wizards')
+makedepends=('ghc' 'haskell-test-framework' 'haskell-test-framework-hunit')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('0c66b176a1846a023aca63e7afd2cab1abe075cd40e0980220dc28507164e0aae79dae2d39014f7a104ea0bc109ce6ca1acd3b445e9f8dd65cf9e84e0b58de74')
+
+prepare() {
+    # It does nothing
+    sed -e '/mtl-compat/d' -e 's/< *4.12/<5/' \
+        -i ${pkgname}-${pkgver}/${pkgname}.cabal
+}
+
+build() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -fterminfo -fthreaded
+    LC_CTYPE=en_US.UTF-8 runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}