[arch-commits] Commit in pandoc/repos (2 files)

[Felix Yan]

    Date: Friday, October 19, 2018 @ 14:11:34
  Author: felixonmars
Revision: 397576

archrelease: copy trunk to community-staging-x86_64

Added:
  pandoc/repos/community-staging-x86_64/
  pandoc/repos/community-staging-x86_64/PKGBUILD
    (from rev 397575, pandoc/trunk/PKGBUILD)

----------+
 PKGBUILD |   69 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)

Copied: pandoc/repos/community-staging-x86_64/PKGBUILD (from rev 397575, pandoc/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-10-19 14:11:34 UTC (rev 397576)
@@ -0,0 +1,69 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=pandoc
+pkgver=2.3.1
+pkgrel=14
+pkgdesc="Conversion between markup formats"
+url="http://pandoc.org"
+license=("GPL")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-http' 'haskell-juicypixels' 'haskell-sha' 'haskell-aeson'
+         'haskell-aeson-pretty' 'haskell-base-compat' 'haskell-base64-bytestring'
+         'haskell-blaze-html' 'haskell-blaze-markup' 'haskell-case-insensitive' 'haskell-cmark-gfm'
+         'haskell-data-default' 'haskell-doctemplates' 'haskell-exceptions' 'haskell-glob'
+         'haskell-haddock-library' 'haskell-skylighting' 'haskell-hslua'
+         'haskell-hslua-module-text' 'haskell-http-client' 'haskell-syb' 'haskell-hsyaml' 'haskell-http-client-tls'
+         'haskell-http-types' 'haskell-safe' 'haskell-split' 'haskell-texmath'
+         'haskell-network' 'haskell-pandoc-types' 'haskell-random'
+         'haskell-tagsoup' 'haskell-temporary' 'haskell-network-uri'
+         'haskell-unordered-containers' 'haskell-zip-archive' 'haskell-vector' 'haskell-xml'
+         'haskell-zlib')
+optdepends=('pandoc-citeproc: for citation rendering with pandoc-citeproc filter'
+            'pandoc-crossref: for numbering figures, equations, tables and cross-references to them with pandoc-crossref filter'
+            'texlive-core: for pdf output')
+conflicts=('haskell-pandoc')
+replaces=('haskell-pandoc')
+makedepends=('ghc' 'haskell-diff' 'haskell-tasty' 'haskell-tasty-hunit' 'haskell-tasty-quickcheck'
+             'haskell-tasty-golden' 'haskell-quickcheck' 'haskell-executable-path')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz"
+        https://github.com/jgm/pandoc/commit/58eb78c437a411ee796e2c90d7c4681fe78d8254.patch)
+sha512sums=('e1c708e828c48ce5cf2a8a00431c0d75750ec46a67389de04260f3e18845b67a7e4792ea862e6184da00d335f1567f1276af4bddbb8d5275b3913f1b3a752121'
+            'bf5aa3cf3628c52d1cd535b2a39a6ac3f158db828923da677870186ff1db80f1cb47f67c136496759a0a49a9f77a6fb89ac16ed3561af1ce50350ee17a3826d0')
+
+prepare() {
+    cd "${srcdir}/$pkgname-${pkgver}"
+    patch -p1 -i ../58eb78c437a411ee796e2c90d7c4681fe78d8254.patch
+
+    sed -i 's/< *0.6/<1/' $pkgname.cabal
+
+    # TODO: find a better solution
+    sed -i "s|let env' = dynlibEnv ++ |let env' = dynlibEnv ++ [(\"LD_LIBRARY_PATH\", \"$PWD/dist/build\")] ++ |" test/Tests/Command.hs
+}
+
+build() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgbase}" --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-trypandoc -f-embed_data_files -f-static
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    LC_CTYPE=en_US.UTF-8 runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${pkgbase}-${pkgver}"
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/COPYING.md"
+}