[arch-commits] Commit in cloudprint-cups/trunk (PKGBUILD cloudprint-cups.install)
Filipe Laíns
ffy00 at archlinux.org
Sat Oct 20 20:44:56 UTC 2018
Date: Saturday, October 20, 2018 @ 20:44:56
Author: ffy00
Revision: 398127
upgpkg: cloudprint-cups 1:20160502.r16.g1f27903-1
Added:
cloudprint-cups/trunk/PKGBUILD
cloudprint-cups/trunk/cloudprint-cups.install
-------------------------+
PKGBUILD | 42 ++++++++++++++++++++++++++++++++++++++++++
cloudprint-cups.install | 8 ++++++++
2 files changed, 50 insertions(+)
Added: PKGBUILD
===================================================================
--- PKGBUILD (rev 0)
+++ PKGBUILD 2018-10-20 20:44:56 UTC (rev 398127)
@@ -0,0 +1,42 @@
+# Maintainer: Filipe Laíns (FFY00) <lains at archlinux.org>
+
+pkgname=cloudprint-cups
+_gitname=CUPS-Cloud-Print
+_commit=1f279036fad249efa8a2bca7f8f54adffd3b59c8
+pkgver=20160502.r16.g1f27903
+pkgrel=1
+epoch=1
+pkgdesc='Google Cloud Print driver for CUPS, allows printing to printers hosted on GCP.'
+arch=('any')
+url='https://github.com/simoncadman/CUPS-Cloud-Print'
+license=('GPL3')
+depends=('cups' 'imagemagick' 'ghostscript' 'python2-pycups' 'python2' 'python2-httplib2' 'python2-six')
+makedepends=('git')
+install=$pkgname.install
+source=("git://github.com/simoncadman/CUPS-Cloud-Print.git#commit=$_commit")
+sha512sums=('SKIP')
+
+pkgver() {
+ cd $_gitname
+
+ git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+ cd $_gitname
+
+ ./configure --prefix /usr
+
+ make
+}
+
+package() {
+ cd $_gitname
+
+ NOPERMS=1 make DESTDIR="$pkgdir" install
+ python2 -O -m compileall "$pkgdir"/usr/share/$pkgname
+
+ install -dm 755 "$pkgdir"/usr/bin
+ ln -sf /usr/share/$pkgname/setupcloudprint.py "$pkgdir"/usr/bin/setupcloudprint
+}
+
Added: cloudprint-cups.install
===================================================================
--- cloudprint-cups.install (rev 0)
+++ cloudprint-cups.install 2018-10-20 20:44:56 UTC (rev 398127)
@@ -0,0 +1,8 @@
+post_install() {
+ echo 'Run setupcloudprint to connect to your Google account'
+}
+
+post_upgrade() {
+ /usr/share/cloudprint-cups/upgrade.py
+}
+
More information about the arch-commits
mailing list