[arch-commits] Commit in tracker/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Evangelos Foutras]

    Date: Monday, October 22, 2018 @ 20:08:10
  Author: foutrelis
Revision: 337056

archrelease: copy trunk to staging-x86_64

Added:
  tracker/repos/staging-x86_64/
  tracker/repos/staging-x86_64/PKGBUILD
    (from rev 337055, tracker/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: tracker/repos/staging-x86_64/PKGBUILD (from rev 337055, tracker/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2018-10-22 20:08:10 UTC (rev 337056)
@@ -0,0 +1,45 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Alexander Fehr <pizzapunk gmail com>
+
+pkgname=tracker
+pkgver=2.1.5
+pkgrel=3
+pkgdesc="Desktop-neutral user information store, search tool and indexer"
+url="https://wiki.gnome.org/Projects/Tracker"
+arch=(x86_64)
+license=(GPL)
+depends=(sqlite icu glib2 libffi util-linux libstemmer libseccomp libsoup json-glib upower libnm)
+makedepends=(gobject-introspection intltool vala git gtk-doc bash-completion meson)
+checkdepends=(python2-gobject python2-dbus)
+groups=(gnome)
+_commit=e1cdde255348b11cf98a33e4b3c37ae5a77b5147  # tags/2.1.5^0
+source=("git+https://gitlab.gnome.org/GNOME/tracker.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  # LTO breaks due to duplicate types:
+  # https://gitlab.gnome.org/GNOME/tracker/issues/44
+  arch-meson $pkgname build -D b_lto=false
+  ninja -C build
+}
+
+check() {
+  # Many tests are broken:
+  # - Assume schemas are installed
+  # - Assume services are autolaunched
+  dbus-run-session meson test -C build || :
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}